windows - 从 Windows 脚本发送邮件

Question

我想通过 Windows Server 2003 Standard Edition 上的脚本发送邮件。我认为服务器设置几乎是开箱即用的。

邮件服务器是 Exchange 服务器，当您在内部网络上时，您可以使用普通的旧 SMTP。我在我的机器上用 Perl 完成了它，但不幸的是 Perl 在服务器上不可用。

有没有一种简单的方法可以从 .bat 文件或任何其他不需要安装一些额外软件的方式来做到这一点？

编辑:
感谢您的快速回复。 "blat"thingie 可能会工作正常，但使用 wscript 我不必使用单独的二进制文件。

我第一次编辑和选择答案时没有看到 PhiLho 的帖子。我无需在此处复制代码。

只需将脚本保存到一个文件中，比如 sendmail.vbs，然后从命令提示符中调用它，如下所示:
wscript 发送邮件.vbs

Answer 1

可以使用 Wscript，使用 CDO:

Dim objMail

Set objMail = CreateObject("CDO.Message")

objMail.From = "Me <Me@Server.com>"
objMail.To = "You <You@AnotherServer.com>"
objMail.Subject = "That's a mail"
objMail.Textbody = "Hello World"
objMail.AddAttachment "C:\someFile.ext"

---8<----- You don't need this part if you have an active Outlook [Express] account -----
' Use an SMTP server
objMail.Configuration.Fields.Item _
    ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

' Name or IP of Remote SMTP Server
objMail.Configuration.Fields.Item _
    ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = _
    "smtp.server.com"

' Server port (typically 25)
objMail.Configuration.Fields.Item _
    ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25

objMail.Configuration.Fields.Update
----- End of SMTP usage ----->8---

objMail.Send

Set objMail=Nothing
Wscript.Quit

更新:在那里找到更多信息:VBScript To Send Email Using CDO 默认情况下，它似乎使用 Outlook [Express]，因此它在我的计算机上不起作用，但您可以使用给定的 SMTP 服务器，这对我来说效果很好。