python - 在 cython 中编写未知维度的 numpy 代码

Question

假设我有一个 Cython 代码，其中的函数计算滚动移动平均值并返回与输入大小相同的数组(该函数为初始部分添加了 nan，但这不是对于当前的问题很重要)。

我编写了三个 Cython 函数(如下所示):

(a) sma_vec 处理一维的 numpy 数组

(b) sma_mat 处理二维 numpy 数组

(c) 第三个 sma 根据大小从 sma_vec 或 sma_mat 返回值。 (我的动机是最终将 sma_vec 或 sma_mat 之前的 cpdef 替换为 cdef，以便 Python 代码只看到sma 函数)

函数 1 - 处理一维的 numpy 数组

cimport cython
import numpy as np
cimport numpy as np
from numpy cimport ndarray as ar
ctypedef double dtype_t

@cython.boundscheck(False)
@cython.wraparound(False)
cpdef sma_vec(ar[dtype_t, ndim=1] x, int m):
    cdef int n
    cdef Py_ssize_t i, j
    cdef ar[dtype_t, ndim=1] y
    if m == 1:
        return x.copy()
    else:
        y = np.zeros_like(x) * np.nan
        n = x.shape[0]
        if n < m:
            return y
        else:
            for i in range(m-1, n):
                for j in range(i-m+1, i+1):
                    if j == i-m+1:
                        y[i] = x[j]
                    else:
                        y[i] += x[j]
                y[i] /= float(m)
            return y

函数 2 - 处理二维 numpy 数组(在 ndarray 的每一行上调用函数 1)

@cython.boundscheck(False)
@cython.wraparound(False)
cpdef sma_mat(ar[dtype_t, ndim=2] x, int m):
    cdef int n
    cdef Py_ssize_t i
    cdef ar[dtype_t, ndim=2] y
    if m == 1:
        return x.copy()
    else:
        y = np.zeros_like(x) * np.nan
        n = x.shape[0]
        if n < m:
            return y
        else:
            for i in range(0, x.shape[0]):
                y[i] = sma_vec(x[i], m)
            return y

函数3-根据维度调用函数1或函数2

@cython.boundscheck(False)
@cython.wraparound(False)
cpdef sma(ar[dtype_t] x, int m):
    if x.ndim == 1:
        return sma_vec(x, m)
    elif x.ndim == 2:
        return sma_mat(x, m)
    else:
        raise ValueError('Cannot handle more than two dimensions')

测试代码

import numpy as np
import common.movavg as mv

x1 = np.array([1.0, 1.4, 1.3, 5.3, 2.3])
y1 = mv.sma_vec(x1, 3)
y1a = mv.sma(x1, 3)

y1 和 y1a 均正确返回 array([nan, nan, 1.233333, 2.666667, 2.966667])

x2 = np.array([[1.0, 1.4, 1.3, 5.3, 2.3], [4.2, 1.3, 2.3, 5.7, -1.3]])
y2 = mv.sma_mat(x2, 2)

y2 正确返回

array([[  nan,  1.2 ,  1.35,  3.3 ,  3.8 ],
       [  nan,  2.75,  1.8 ,  4.  ,  2.2 ]])

但是当我尝试时:

y2a = mv.sma(x2, 2)

我收到错误:

Traceback (most recent call last):
  File "C:\PF\WinPython-64bit-3.4.2.4\python-3.4.2.amd64\lib\site-packages\IPython\core\interactiveshell.py", line 2883, in run_code
exec(code_obj, self.user_global_ns, self.user_ns)
  File "<ipython-input-4-dc092e343714>", line 3, in <module>
    y2a = mv.sma(x2, 2)
  File "movavg.pyx", line 54, in movavg.sma (stat\movavg.c:2206)
ValueError: Buffer has wrong number of dimensions (expected 1, got 2)

在sma函数中，问题似乎是ar[dtype_t] x(即np.ndarray[double] x)自动假定 x.ndim 的尺寸应为 1。

如何重写 sma 函数，以便它可以接受尺寸未知的 np.ndarray ？

Answer 1

找到了答案。

从此链接:numpy_tutorial ，“...“ndim”仅关键字参数，如果未提供，则假定为一维...”

解决办法是将函数3转换为:

@cython.boundscheck(False)
@cython.wraparound(False)
cpdef sma(ar x, int m):
    if x.ndim == 1:
        return sma_vec(x, m)
    elif x.ndim == 2:
        return sma_mat(x, m)
    else:
        raise ValueError('Cannot handle more than two dimensions')

我们需要完全删除[]中的所有内容。