当我点击显示窗口上的任意位置时,直径为 10 的圆(以下称为节点)应显示在该点。先前单击的节点应保留在屏幕上,并且应该有线条将每个节点与下一个节点连接起来(最后一个节点连接到第一个节点)。除了这些线(当然还有网格线)之外,不应该有其他线。
当我点击任何位置时,节点应该在最近的网格交点处生成。
//code for grid
int n_part=10;
void setup () {
size (600, 360);
}
void draw () {
background (255);
int gridW= width/n_part;
int gridH=height/n_part;
stroke(210);
for (int row = 0; row < n_part; row++){
int gridY = 0 + row*gridH;
for (int col = 0; col < n_part; col++) {
int gridX = 0+ col* gridW;
rect (gridX, gridY, gridW, gridH);
}
}
}
我希望当我在网格上单击鼠标时,节点应该出现在最近的网格上。再次单击鼠标后,应该会出现另一个节点以及这两个节点之间的边缘。
最佳答案
创建一个可以存储点及其大小(半径)的类。该类有一个构造函数和一个分别绘制点圆的方法。
class Point {
int x, y, r;
Point(int x, int y, int r) {
this.x = x;
this.y = y;
this.r = r;
}
void Draw() {
circle(this.x, this.y, this.r*2);
}
}
使用ArrayList
Point 对象来存储点
ArrayList<Point> points = new ArrayList<Point>();
使用mousePressed()
用于将新点添加到列表的事件回调
void mousePressed() {
int gridW = width/n_part;
int gridH = height/n_part;
int x = round(mouseX / (float)gridW) * gridW;
int y = round(mouseY / (float)gridH) * gridH;
points.add(new Point(x, y, 5));
}
在循环中绘制点。可以通过在列表中的连续点之间绘制 line()
来创建线条。例如:
void draw () {
background (255);
int gridW = width/n_part;
int gridH = height/n_part;
strokeWeight(1);
stroke(210);
noFill();
for (int row = 0; row < n_part; row++){
int gridY = 0 + row*gridH;
for (int col = 0; col < n_part; col++) {
int gridX = 0+ col* gridW;
rect (gridX, gridY, gridW, gridH);
}
}
strokeWeight(3);
stroke(0, 0, 255);
for (int i = 0; i < points.size(); ++ i) {
Point p1 = points.get(i);
Point p2 = points.get((i+1) % points.size());
line(p1.x, p1.y, p2.x, p2.y);
}
strokeWeight(1);
stroke(0, 0, 0);
fill (255, 0, 0);
for (int i = 0; i < points.size(); ++ i) {
Point p = points.get(i);
p.Draw();
}
}
关于java - 什么类型的数组(代码)适用于这个问题?,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/58533932/