我在 Visual Studio Community 2015 中下载文本文件时遇到问题。它是我的 OneDrive 公共(public)文件夹中的一个文本文件,其中包含我的应用程序的版本号 (1.0.0.0)。我使用的下载链接在手动打开时工作正常,但是当我的 VB 代码执行时,它确实正确下载了文本文件,但是当我打开它时文件是空白的,我无法弄清楚哪里出了问题。
在模块 1 中,我有一个用于下载的子程序和一个用于随后读取文件的子程序:
Module Module1
' Public variables
Public tempPath As String = Environment.GetFolderPath(Environment.SpecialFolder.LocalApplicationData) & "\Temp"
Sub DownloadToTemp(filePath As String)
' Download a text file, ready to read contents
If Not IO.Directory.Exists(tempPath & "\Temp") Then
IO.Directory.CreateDirectory(tempPath & "\Temp")
End If
Try
My.Computer.Network.DownloadFile _
(address:=filePath,
destinationFileName:=tempPath & "\TempText.txt",
userName:=String.Empty,
password:=String.Empty,
showUI:=False,
connectionTimeout:=10000,
overwrite:=True)
Catch ex As Exception
MsgBox("Can't read file" & vbCrLf & ex.Message)
End Try
End Sub
Sub ReadFile()
Dim fStream As New IO.FileStream(tempPath & "\TempText.txt", IO.FileMode.Open)
Dim sReader As New System.IO.StreamReader(fStream)
Dim sArray As String() = Nothing
Dim index As Integer = 0
Do While sReader.Peek >= 0
ReDim Preserve sArray(index)
sArray(index) = sReader.ReadLine
index += 1
Loop
fStream.Close()
sReader.Close()
' Test
Dim fileContents As String = Nothing
If sArray Is Nothing Then
MsgBox("No Data Found")
Exit Sub
End If
For index = 0 To UBound(sArray)
fileContents = fileContents & sArray(index) & vbCrLf
Next
MessageBox.Show(fileContents)
End Sub
End Module
它们是从主代码中调用的:
Private Sub frmSplash_Load(sender As Object, e As EventArgs) Handles MyBase.Load
lblVersion.Text = "v" & Application.ProductVersion
' Check available version online
Call DownloadToTemp("https://onedrive.live.com/download?resid=DE2331D1649390C1!16974&authkey=!AH2cr1S1SHs9Epk&ithint=file%2ctxt")
Call ReadFile()
End Sub
所以,一切似乎都是正确的,没有错误或异常,但我的 VB 代码下载的文件是空白的,但手动单击代码中的下载链接会下载内容完整的文件。谁能看出为什么会这样?
最佳答案
该代码将下载该位置的任何内容,但该链接似乎会将您重定向到另一个地方。它下载从链接获得的响应,该响应什么也没有,因为那里什么也没有。
您需要文件的直接链接才能正常工作。试试这个:
DownloadToTemp("https://gwhcha-dm2306.files.1drv.com/y4mwlpYyvyCFDPp3NyPM6WqOz8-Ocfn-W0_4RbdQBtNMATYn2jNgWMRgpl_gXdTBteipIevz07_oUjCkeNoJGUxNO9jC9IdXz60NNEvzx2cU9fYJU_oRgqBFyA8KkBs8VGc8gDbs2xz7d3FyFnkgRfq77A2guoosQkO4pVMDiEYRoJRCWOtQk2etsMXyT8nSEnPoGV6ZG0JWc6qt55Mhi_zeA/Hotshot_Version.txt?download&psid=1")
此外,您不需要使用 Call
keyword .它的存在只是为了向后兼容 VB6 和旧版本。
编辑:
这是使用 HttpWebRequest
class 下载文件的示例.通过设置其 AllowAutoRedirect
和 MaximumAutomaticRedirections
您允许它在尝试下载文件之前重定向的属性。
''' <summary>
''' Downloads a file from an URL and allows the page to redirect you.
''' </summary>
''' <param name="Url">The URL to the file to download.</param>
''' <param name="TargetPath">The path and file name to download the file to.</param>
''' <param name="AllowedRedirections">The maximum allowed amount of redirections (default = 32).</param>
''' <param name="DownloadBufferSize">The amount of bytes of the download buffer (default = 4096 = 4 KB).</param>
''' <remarks></remarks>
Private Sub DownloadFileWithRedirect(ByVal Url As String, _
ByVal TargetPath As String, _
Optional ByVal AllowedRedirections As Integer = 32, _
Optional ByVal DownloadBufferSize As Integer = 4096)
'Create the request.
Dim Request As HttpWebRequest = DirectCast(WebRequest.Create(Url), HttpWebRequest)
Request.Timeout = 10000 '10 second timeout.
Request.MaximumAutomaticRedirections = AllowedRedirections
Request.AllowAutoRedirect = True
'Get the response from the server.
Using Response As HttpWebResponse = DirectCast(Request.GetResponse(), HttpWebResponse)
'Get the stream to read the response.
Using ResponseStream As Stream = Response.GetResponseStream()
'Declare a download buffer.
Dim Buffer() As Byte = New Byte(DownloadBufferSize - 1) {}
Dim ReadBytes As Integer = 0
'Create the target file and open a file stream to it.
Using TargetFileStream As New FileStream(TargetPath, FileMode.Create, FileAccess.Write, FileShare.None)
'Start reading into the buffer.
ReadBytes = ResponseStream.Read(Buffer, 0, Buffer.Length)
'Loop while there's something to read.
While ReadBytes > 0
'Write the read bytes to the file.
TargetFileStream.Write(Buffer, 0, ReadBytes)
'Read more into the buffer.
ReadBytes = ResponseStream.Read(Buffer, 0, Buffer.Length)
End While
End Using
End Using
End Using
End Sub
示例用法:
Try
DownloadFileWithRedirect("https://onedrive.live.com/download?resid=DE2331D1649390C1!16974&authkey=!AH2cr1S1SHs9Epk&ithint=file%2ctxt", Path.Combine(tempPath, "TempText.txt"))
Catch ex As Exception
MessageBox.Show("An error occurred:" & Environment.NewLine & ex.Message, "Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
End Try
关于vb.net - 为什么我的在线文本文件在 VB.NET 中下载为空白?,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/47064146/