python - 如何在我的主模式 Hook 中访问目录局部变量？

Question

我已经定义了一个包含以下内容的 .dir-locals.el 文件:

((python-mode . ((cr/virtualenv-name . "saas"))))

在我的 .emacs 中，我有以下函数来检索此值并提供 virtualenv 路径:

(defun cr/virtualenv ()
  (cond (cr/virtualenv-name (format "%s/%s" virtualenv-base cr/virtualenv-name))
        ((getenv "EMACS_VIRTUAL_ENV") (getenv "EMACS_VIRTUAL_ENV"))
        (t "~/.emacs.d/python")))

最后，在我的 python-mode-hook 列表中，我有这个钩子(Hook)函数:

(add-hook 'python-mode-hook 'cr/python-mode-shell-setup)

(defun cr/python-mode-shell-setup ()
  (message "virtualenv-name is %s" cr/virtualenv-name)
  (let ((python-base (cr/virtualenv)))
    (cond ((and (fboundp 'ipython-shell-hook) (file-executable-p (concat python-base "/bin/ipython")))
           (setq python-python-command (concat python-base "/bin/ipython"))
           (setq py-python-command (concat python-base "/bin/ipython"))
           (setq py-python-command-args '( "-colors" "NoColor")))
          (t
           (setq python-python-command (concat python-base "/bin/python"))
           (setq py-python-command (concat python-base "/bin/python"))
           (setq py-python-command-args nil)))))

当我打开一个新的 python 文件时，cr/python-mode-shell-setup 记录的消息表明 cr/virtualenv-name 是 nil 。但是，当我 C-h v 名称时，我得到的是“saas”。

显然这里存在加载顺序问题；有没有办法让我的模式 Hook 语句响应目录局部变量？

Answer 1

发生这种情况是因为 normal-mode 按顺序调用 (set-auto-mode) 和 (hack-local-variables)。

但是 hack-local-variables-hook 是在处理完局部变量之后运行的，这使得一些解决方案成为可能:

1. 首先是让 Emacs 为每个主要模式运行一个新的“局部变量 Hook ”:

   (add-hook 'hack-local-variables-hook 'run-local-vars-mode-hook)
   (defun run-local-vars-mode-hook ()
     "Run a hook for the major-mode after the local variables have been processed."
     (run-hooks (intern (concat (symbol-name major-mode) "-local-vars-hook"))))
   
   (add-hook 'python-mode-local-vars-hook 'cr/python-mode-shell-setup)
   

   (通过这种方法，您的原始函数可以不加修改地使用。)

2. 第二个选项是使用可选的 LOCAL 参数给 add-hook 使指定的函数成为局部缓冲区。使用这种方法，您可以按如下方式编写钩子(Hook):

   (add-hook 'python-mode-hook 'cr/python-mode-shell-setup)
   
   (defun cr/python-mode-shell-setup ()
     (add-hook 'hack-local-variables-hook
               (lambda () (message "virtualenv-name is %s" cr/virtualenv-name)
                 (let ((python-base (cr/virtualenv)))
                   (cond ((and (fboundp 'ipython-shell-hook) (file-executable-p (concat python-base "/bin/ipython")))
                          (setq python-python-command (concat python-base "/bin/ipython"))
                          (setq py-python-command (concat python-base "/bin/ipython"))
                          (setq py-python-command-args '( "-colors" "NoColor")))
                         (t
                          (setq python-python-command (concat python-base "/bin/python"))
                          (setq py-python-command (concat python-base "/bin/python"))
                          (setq py-python-command-args nil)))))
               nil t)) ; buffer-local hack-local-variables-hook
   

   即python-mode-hook 首先运行并使用 hack-local-variables-hook 为当前缓冲区注册匿名函数；然后在处理完局部变量后调用该函数。

3. Lindydancer 的评论提示了第三种方法。它不像其他两个那样干净，但无论如何都证明很有趣。我不喜欢让 (hack-local-variables) 被调用两次的想法，但我发现如果你设置 local-enable-local-variables缓冲区本地，它阻止 (hack-local-variables) 做任何事情，所以你可以这样做:

   (defun cr/python-mode-shell-setup ()
     (report-errors "File local-variables error: %s"
       (hack-local-variables)))
     (set (make-local-variable 'local-enable-local-variables) nil)
     (let ((python-base (cr/virtualenv)))
       ...))
   

   显然，这会稍微修改正常的执行顺序，因此可能会产生副作用。我担心如果文件中的局部变量 comment 设置相同的主模式，这可能会导致无限递归，但这实际上似乎不是问题。

   局部变量 header 注释(例如 -*- mode: foo -*-)由 (set-auto-mode) 处理，所以这些没问题；但是 mode: foo Local Variables: 注释似乎是个问题，因为它由 (hack-local-variables) 处理，因此，如果以这种方式设置模式，我认为它会导致递归。

   在实践中，我能够通过使用一个简单的函数作为“模式”来触发这个问题，它只是尝试运行它的钩子(Hook)；然而，使用“适当”模式进行测试并没有出现问题，因此它在现实中可能是安全的。我没有进一步研究这个(因为其他两个解决方案比这个更清晰)，但我猜延迟模式 Hook 机制可能解释了它？