c++ - LNK1146 : no argument specified with option '/LIBPATH:' error in Qt

Question

我将我在 linux 上开发的 Qt 应用程序导入到 windows 中。现在，当我构建项目时出现此错误:

 error: LNK1146: no argument specified with option '/LIBPATH:'

我在 Windows 上创建了一个新项目，它运行良好。导致这种情况的一个可能原因是项目路径中有空格，但我的项目路径中没有空格。你能告诉我如何解决这个问题吗？

这是我的 .pro 文件:

#-------------------------------------------------
#
# Project created by QtCreator 2014-12-08T09:19:31
#
#-------------------------------------------------

QT       += core gui


greaterThan(QT_MAJOR_VERSION, 4): QT += widgets




TARGET = FirstProject
TEMPLATE = app
QMAKE_CXXFLAGS += -std=c++11

SOURCES += main.cpp\
        firstscreen.cpp \
        secondscreen.cpp \
        thirdscreen.cpp

INCLUDEPATH += C:\Users\user_name\tango\ \
               C:\Users\user_name\omniORB4\ \
               C:\Users\user_name\omnithread.h





HEADERS  += firstscreen.h \
            C:\Users\user_name\tango\ \
            C:\Users\user_name\omniORB4\ \
            C:\Users\user_name\omnithread.h \
            secondscreen.h \
            thirdscreen.h


LIBS += -L -lomnithread \
        -L -lomniORB4 \
        -L -ltango


FORMS    += firstscreen.ui \
            secondscreen.ui \
            thirdscreen.ui

Answer 1

问题的发生是因为指定了标志 -L，但没有给出库路径:

LIBS += -L -lomnithread \
        -L -lomniORB4 \
        -L -ltango

要解决此问题，您必须提供 .lib 文件所在的路径，类似于:

LIBS += -L"C:\\Users\\user_name\\omnithread\\lib"  -lomnithread \
        -L"C:\\Users\\user_name\\omniORB4\\lib" -lomniORB4 \
        -L"C:\\Users\\user_name\\tango\\lib" -ltango

记住:-L 和路径字符串之间不能有空格。

所以这样做也会抛出同样的错误:

LIBS += -L "C:\\Users\\user_name\\omnithread\\lib"  -lomnithread \
        -L "C:\\Users\\user_name\\omniORB4\\lib" -lomniORB4 \
        -L "C:\\Users\\user_name\\tango\\lib" -ltango