python - 你能同时检查机器人框架中的多个 URL 吗？

Question

我正在编辑我原来的问题，希望这表明我做了更多的研究

我想我找到了一种方法，但是，我卡在了某件事上，我发现我可以使用 for 循环 来遍历 url 列表，我的问题是，对于任何后续步骤，例如 capture page screenshot 或 press key 等，我应该在哪里应用这些步骤？它们也嵌套在循环中吗？

我看到了另一个 stackoverflow 帖子，它给了我这个想法:

*** Variables ***
@{HOMEPAGES}     http://example.one    http://example.two   http://example.three
${BROWSER}      ff

*** Test Cases ***
test with several links
    :FOR    ${homepage}     IN      @{HOMEPAGES}
    \   open browser     ${homepage}
    \   capture page screenshot     ${homepage}

上面的例子给了我一个通过，但我想知道如果我想将这些操作应用于 @{HOMEPAGES}，是否必须将每个操作都放在 for 循环 中数组？

Answer 1

有两种或多或少的标准方法来处理您的任务。 您可以使用 data-driven test :

*** Settings ***
Test Template     Make Screenshots

*** Test Cases ***    Web Page
Page one              http://example.one
Page two              http://example.two
Page three            http://example.three

*** Keywords ***
Make Screenshots
  [Arguments]  ${homepage}
  Open Browser     ${homepage}    ff
  Capture Page Screenshot

或者简单地使用自定义关键字来对所需的操作进行分组:

*** Variables ***
@{HOMEPAGES}     http://example.one    http://example.two    http://example.three
${BROWSER}      ff

*** Test Cases ***
test with several links
    :FOR    ${homepage}     IN      @{HOMEPAGES}
    \   Make Screenshots  ${homepage}

*** Keywords ***
Make Screenshots
  [Arguments]  ${homepage}
  Open Browser     ${homepage}    ${BROWSER}
  Capture Page Screenshot

就个人而言，我会选择数据驱动的测试，因为它更优雅且更易于扩展。