c# - 由方法调用组成的简单 DSL 的 Lexer/Parser

Question

我希望为我们使用内部工具的简单 DSL 创建词法分析器和解析器。将有几个内置符号(这是正确的术语吗？)，它们将采用 1 到 10 个参数。例如:

foo(bar1;bar2)

在运行时还会添加始终具有零参数的符号。示例:

testy1()

这些将被串在一起并从 CSV 文件中读取。组装线会像:

foo(bar1:bar2)testy1()

我很难在网上找到可以轻松解释像这样的词法分析和解析函数调用的资源。有人可以指出我的好方向或提供建议吗？

Answer 1

我用 PegJS 编写了一个小型解析器，它能够解析函数调用中的简单表达式。 PEG 避免了歧义，并且在这方面效果很好。

Start
  = Expr

/* Expressions */

Expr
  = FuncCall
  / Literal

RestExpr
  = _ ( "," / ":" ) _ e:Expr {
    return e;
  }

/* Function call */

FuncCall
  = func:Ident _ "(" _ x:Expr? xs:RestExpr* _ ")" {
    return {
      type: "FuncCall",
      func: func.value,
      params: x ? [x].concat(xs) : []
    };
  }

/* Literals */

Literal
  = Number
  / Ident

Number
  = val:[0-9]+ {
    return {
      type: "Number",
      value: parseInt(val.join(""))
    };
  }

/* Identifier */

Ident
  = x:IdentStart xs:IdentRest* {
  return {
    type: "Ident",
    value: [x].concat(xs).join("")
  };
}

IdentStart
  = [a-z_]i

IdentRest
  = [a-z0-9_]i
_
  = [ \s\t\r\n]*

您可以在这里测试解析器:http://pegjs.org/online

输入示例是 foo(1, bar(2), baz(3))，其中输出是:

{
   "type": "FuncCall",
   "func": "foo",
   "params": [
      {
         "type": "Number",
         "value": 1
      },
      {
         "type": "FuncCall",
         "func": "bar",
         "params": [
            {
               "type": "Number",
               "value": 2
            }
         ]
      },
      {
         "type": "FuncCall",
         "func": "baz",
         "params": [
            {
               "type": "Number",
               "value": 3
            }
         ]
      }
   ]
}

这显然不是最好的方法，但我相信 peg-sharp 可以用 C# 做得很好:https://code.google.com/p/peg-sharp/ .