看看我的语法
grammar protocol;
options {
language = Java;
output = AST;
}
//imaginary tokens
tokens{
BOOL;
CHAR;
STRING;
}
parse
: declaration
;
declaration
: variable
;
variable
: locals
;
locals
: (bool
| char
| string)+
;
bool
:'bool' ID -> ^(BOOL ID)
;
char
: 'char' ID -> ^(CHAR ID)
;
string
:'string' ID -> ^(STRING ID)
;
ID
: (('a'..'z' | 'A'..'Z'|'_')('a'..'z' | 'A'..'Z'|'0'..'9'|'_'))*
;
INT
: ('0'..'9')+
;
WHITESPACE
: ('\t' | ' ' | '\r' | '\n' | '\u000C')+ {$channel = HIDDEN;}
;
对于下面的输入,
bool boolVariable
char charVariable
string stringVariable
我的语法创建了以下 AST
我不能多次声明一个变量。我不想一次声明相同类型的变量,用逗号分隔,但我想要这样
bool boolVariable1
bool boolVariable2
bool boolVariable3
string stringVariable1
string stringVariable2
完成此操作后,我希望所有变量都属于两种主要类型。共享和本地。在 Java 中,共享变量(静态)是对所有对象都有一个副本的变量,而局部变量对每个对象都有单独的副本。我希望用户在定义变量集之前明确指定变量的范围。喜欢,
locals:
bool boolVariable1
bool boolVariable2
bool boolVariable3
string stringVariable1
string stringVariable2
shared:
bool boolVariable4
bool boolVariable5
bool boolVariable6
string stringVariable3
string stringVariable4
char charVariable1
此外,有什么方法可以检查用户不能有两个同名变量吗?喜欢,
bool boolVariable
bool boolVariable
应该给出某种错误或类似的错误。
有什么想法/帮助吗?
谢谢
编辑 - 解决方案
grammar protocol;
options {
language = Java;
output = AST;
}
//imaginary tokens
tokens{
BOOL;
CHAR;
STRING;
SBOOL;
SCHAR;
SSTRING;
}
parse
: declaration
;
declaration
: variable
;
variable
: (locals
| shared)*
;
locals
: 'locals:' (bool| char| string)*
;
bool
:'bool' ID -> ^(BOOL ID)
;
char
: 'char' ID -> ^(CHAR ID)
;
string
:'string' ID -> ^(STRING ID)
;
shared
: 'shared:' (sbool| schar| sstring)*
;
sbool
:'bool' ID -> ^(SBOOL ID)
;
schar
: 'char' ID -> ^(SCHAR ID)
;
sstring
:'string' ID -> ^(SSTRING ID)
;
ID
: (('a'..'z' | 'A'..'Z'|'_')('a'..'z' | 'A'..'Z'|'0'..'9'|'_'))*
;
INT
: ('0'..'9')+
;
WHITESPACE
: ('\t' | ' ' | '\r' | '\n' | '\u000C')+ {$channel = HIDDEN;}
;
最佳答案
正如 Bahdan 在 his answer 中提到的那样,您需要维护一组已被使用的名称。这是一个基于您更新的语法的简单示例(还有一些其他更改,在此答案的底部进行了描述)。新规则 var
是使用新成员(member)代码的地方。请注意,这里没有进行真正的错误处理,只是名称检查。
grammar protocol;
options {
language = Java;
output = AST;
}
//imaginary tokens
tokens{
BOOL;
CHAR;
STRING;
SBOOL;
SCHAR;
SSTRING;
}
@parser::header {
import java.util.ArrayList;
}
@members {
private ArrayList<String> variableNames = new ArrayList<String>();
private boolean variableDefined(String name){
return variableNames.contains(name);
}
private void defineVariable(String name){
variableNames.add(name);
}
}
parse
: declaration
;
declaration
: variable
;
variable
: (locals | shared)*
;
locals
: 'locals:' (bool| char_ | string)*
;
bool
:'bool' var -> ^(BOOL var)
;
char_
: 'char' var -> ^(CHAR var)
;
string
:'string' var -> ^(STRING var)
;
shared
: 'shared:' (sbool| schar| sstring)*
;
sbool
:'bool' var -> ^(SBOOL var)
;
schar
: 'char' var -> ^(SCHAR var)
;
sstring
:'string' var -> ^(SSTRING var)
;
var
: ID
{!variableDefined($ID.text)}? //This rule is only satisfied if the variable is new.
{defineVariable($ID.text);} //we made it here, so it's new. Add it for future reference.
;
ID
: ('a'..'z' | 'A'..'Z'|'_')('a'..'z' | 'A'..'Z'|'0'..'9'|'_')*
;
INT
: ('0'..'9')+
;
WHITESPACE
: ('\t' | ' ' | '\r' | '\n' | '\u000C')+ {$channel = HIDDEN;}
;
I can declare two variables like bool boolVariable bool boolVariable but I can't declare two variables like bool boolVariable bool boolVariable12
查看上面我对 ID
的更改。有一组额外的括号打乱了规则。我还将 char
重命名为 char_
以使解析器为我正确编译。
关于java - 变量的 ANTLR 语法,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/13454437/