postgresql - 在 Vagrant 上使用 Puppet 配置 PostgreSQL

Question

鉴于我不是 Puppet DSL 方面的专家，而且我对 Puppet 还很陌生，所以我有一个 Puppet list 阻止了我让它正常工作的尝试，我还没有设法解决这个问题。

我正在尝试使用 puppetlabs posgres 模块安装 Postgres，创建默认角色，并修复数据库以在 UTF8 上工作。

一切都在运行和安装，但没有创建角色。但是，如果我再次运行该规定，则会创建该角色。我假设可能与执行顺序有关，但老实说我迷路了。

这是我在 list 文件中使用的代码。

user { "user_vagrant":
  ensure => "present",
}->
exec { 'apt_update':
  command => 'apt-get update',
  path    => '/usr/bin/'
}

package { ['vim','postgresql-server-dev-9.1','libmysqlclient-dev','nodejs']:
  ensure  => 'installed',
  before  => Class['postgresql::server'],
  require => Exec['apt_update'],
}

class { 'postgresql::server':
  ip_mask_allow_all_users => '0.0.0.0/0',
  listen_addresses        => '*',
  ipv4acls                => ['local all all md5'],
  postgres_password       => 'postgres',
  require                 => User['user_vagrant'],
}

postgresql::server::role { 'vagrant':
  createdb      => true,
  login         => true,
  password_hash => postgresql_password("vagrant", "vagrant"),
  require       => Class['postgresql::server'],
} ->
exec { 'utf8_postgres':
  command => 'pg_dropcluster --stop 9.1 main ; pg_createcluster --start --locale en_US.UTF-8 9.1 main',
  unless => 'sudo -u postgres psql -t -c "\l" | grep template1 | grep -q UTF',
  path    => ['/bin', '/sbin', '/usr/bin', '/usr/sbin'],
}

Answer 1

终于找到了解决应用顺序和 UTF8 问题的正确方法，这迫使我首先尝试“pg_dropcluster”。顺便说一句，这是一个已知问题，这里是问题 url http://projects.puppetlabs.com/issues/4695

这是我用来安装带有 UTF8 和 RVM ruby​​ 的 PostgreSQL 9.1 的整个文件。希望这可以帮助。

模块:
- puppetlabs/apt - 1.4
- puppetlabs/concat - 1.0
- puppet 实验室/stdlib - 4.1.0
- puppetlabs/postgresql - 3.2
- blt04/puppet-rvm - git://github.com/blt04/puppet-rvm.git

stage { 'pre':
  before => Stage['main']
}

class pre_req {
  user { "vagrant":
    ensure => "present",
  }

  exec { 'apt-update':
    command => 'apt-get update',
    path    => '/usr/bin'
  }->
  exec { 'install_postgres':
    command => "/bin/bash -c 'LC_ALL=en_US.UTF-8; /usr/bin/apt-get -y install postgresql'",
  }
}

class { 'pre_req':
  stage => pre
}

package { ['postgresql-server-dev-9.1']:
  ensure  => 'installed',
  before  => Class['postgresql::server']
}

class { 'postgresql::globals':
  encoding => 'UTF8',
  locale   => 'en_US.UTF-8'
}->
class { 'postgresql::server':
  stage                   => main,
  locale                  => 'en_US.UTF-8',
  ip_mask_allow_all_users => '0.0.0.0/0',
  listen_addresses        => '*',
  ipv4acls                => ['local all all md5'],
  postgres_password       => 'postgres',
  require                 => User['vagrant']
}->
postgresql::server::role { 'vagrant':
  createdb      => true,
  login         => true,
  password_hash => postgresql_password("vagrant", "vagrant"),
}

class rvm_install {
  class { 'rvm': version => '1.23.10' }
  rvm::system_user { vagrant: ; }
  rvm_system_ruby {
    "ruby-2.0.0-p247":
    ensure      => "present",
    default_use => false;
  }
  rvm_gemset {
    "ruby-2.0.0-p247@plyze":
    ensure  => present,
    require => Rvm_system_ruby['ruby-2.0.0-p247'];
  }
  rvm_gem {
    "puppet":
    name         => "puppet",
    ruby_version => "ruby-2.0.0-p247",
    ensure       => latest,
    require      => Rvm_system_ruby["ruby-2.0.0-p247"];
  }
  rvm_gem {
    "bundler":
    name         => "bundler",
    ruby_version => "ruby-2.0.0-p247",
    ensure       => latest,
    require      => Rvm_system_ruby["ruby-2.0.0-p247"];
  }
}

class { 'rvm_install':
  require => User['vagrant'],
}