javascript - 向 bison/jison 计算器语言添加函数

Question

我正在尝试扩展 Jison calculator example带有一些简单的功能。我对解析和 bison/jison 比较陌生，但这是我目前所拥有的一些内容:

/* lexical grammar */
%lex

%{
  var funcs = {
    pow: function(a, b) { return Math.pow(a, b); },
    test: function(a) { return a*2; }
  }
%}

%%

\s+                   /* skip whitespace */
[0-9]+("."[0-9]+)?\b  return 'NUMBER'
[a-zA-Z]+             return 'NAME'
","                   return ','
"*"                   return '*'
"("                   return '('
")"                   return ')'
<<EOF>>               return 'EOF'
.                     return 'INVALID'

/lex

%start expressions

%% /* language grammar */
expressions
    : e EOF
      { return $1; }
    ;

expression_list
    : expression_list ',' e
    | e
    ;

e
    : e '*' e
        {$$ = $1*$3;}
    | '(' e ')'
        {$$ = $2;}
    | NUMBER
        {$$ = Number(yytext);}
    | NAME '(' expression_list ')'
        {$$ = funcs[$NAME]($expression_list);}
    ;

问题是函数只获得传递给它们的一个参数。例如:

test(2) -> 4
pow(2,3) -> null

事实上，如果您console.log pow 的参数，看起来b 甚至都没有定义。为什么在将其发送到函数之前不解析整个表达式列表？

Answer 1

下面的代码完成了您的要求。要点:

1. expression_list 的规则现在构建一个实际的值列表，用于被调用的函数。

2. 由 expression_list 构建的列表被传递给 apply 以便它们成为被调用函数的参数(undefined is作为第一个参数，将 this 的值设置为 undefined)。

3. 我已将 console.log 指令添加到 expression 的操作中，以便在运行生成的解析器时看到发生了什么在命令行。

4. 我已将 funcs 的定义移至开头。 jison 只是没有把它放在最终文件中的正确位置。

这是最终文件:

%{var funcs = {
    pow: function(a, b) { return Math.pow(a, b); },
    test: function(a) { return a*2; }
  }
%}

/* lexical grammar */
%lex

%%

\s+                   /* skip whitespace */
[0-9]+("."[0-9]+)?\b  return 'NUMBER'
[a-zA-Z]+             return 'NAME'
","                   return ','
"*"                   return '*'
"("                   return '('
")"                   return ')'
<<EOF>>               return 'EOF'
.                     return 'INVALID'

/lex

%start expressions

%% /* language grammar */
expressions
    : e EOF
      { console.log($1); return $1; }
    ;

expression_list
    : expression_list ',' e
      { $$ = $1.concat([$3]); }
    | e
      { $$ = [$1]; }
    ;

e
    : e '*' e
        {$$ = $1*$3;}
    | '(' e ')'
        {$$ = $2;}
    | NUMBER
        {$$ = Number(yytext);}
    | NAME '(' expression_list ')'
        {$$ = funcs[$NAME].apply(undefined, $expression_list);}
    ;