c# - 在结构上使用 "new"是在堆还是堆栈上分配它？

Question

当您使用 new 创建类的实例时运算符，内存在堆上分配。当您使用 new 创建结构体的实例时运算符在堆上还是在堆栈上分配内存？

Answer 1

好吧，让我们看看我能不能说得更清楚一点。

首先，Ash 是对的:问题不在于值类型变量的分配位置。这是一个不同的问题 - 答案不仅仅是“在堆栈上”。它比那更复杂(并且被 C# 2 变得更加复杂)。我有一个 article on the topic并且会在需要时扩展它，但让我们只处理 new运算符(operator)。

其次，所有这一切实际上取决于您所谈论的级别。我正在查看编译器如何处理源代码，就它创建的 IL 而言。 JIT 编译器很可能会在优化大量“逻辑”分配方面做一些聪明的事情。

第三，我忽略了泛型，主要是因为我实际上并不知道答案，部分原因是它会使事情变得过于复杂。

最后，所有这些都仅适用于当前的实现。 C# 规范并没有详细说明这一点 - 它实际上是一个实现细节。有些人认为托管代码开发人员真的不应该关心。我不确定我会走那么远，但值得想象一个实际上所有局部变量都存在于堆上的世界 - 这仍然符合规范。
new 有两种不同的情况。值类型的运算符:您可以调用无参数构造函数(例如 new Guid() )或有参数构造函数(例如 new Guid(someString) )。这些产生显着不同的IL。要了解原因，您需要比较 C# 和 CLI 规范:根据 C#，所有值类型都有一个无参数构造函数。根据 CLI 规范，没有值类型具有无参数构造函数。 (有时使用反射获取值类型的构造函数-您不会找到无参数的构造函数。)

C# 将“用零初始化值”视为构造函数是有意义的，因为它使语言保持一致——你可以想到 new(...)像往常一样调用构造函数。 CLI 以不同的方式思考它是有意义的，因为没有真正的代码可以调用——当然也没有特定于类型的代码。

初始化值后，您将如何处理该值也会有所不同。 IL 用于

Guid localVariable = new Guid(someString);

与用于以下用途的 IL 不同:

myInstanceOrStaticVariable = new Guid(someString);

此外，如果该值用作中间值，例如方法调用的参数，情况又略有不同。为了显示所有这些差异，这里有一个简短的测试程序。它没有显示静态变量和实例变量之间的区别:IL 在 stfld 之间会有所不同。和 stsfld ，但仅此而已。

using System;

public class Test
{
    static Guid field;

    static void Main() {}
    static void MethodTakingGuid(Guid guid) {}


    static void ParameterisedCtorAssignToField()
    {
        field = new Guid("");
    }

    static void ParameterisedCtorAssignToLocal()
    {
        Guid local = new Guid("");
        // Force the value to be used
        local.ToString();
    }

    static void ParameterisedCtorCallMethod()
    {
        MethodTakingGuid(new Guid(""));
    }

    static void ParameterlessCtorAssignToField()
    {
        field = new Guid();
    }

    static void ParameterlessCtorAssignToLocal()
    {
        Guid local = new Guid();
        // Force the value to be used
        local.ToString();
    }

    static void ParameterlessCtorCallMethod()
    {
        MethodTakingGuid(new Guid());
    }
}

这是该类的 IL，不包括不相关的位(例如 nops):

.class public auto ansi beforefieldinit Test extends [mscorlib]System.Object    
{
    // Removed Test's constructor, Main, and MethodTakingGuid.

    .method private hidebysig static void ParameterisedCtorAssignToField() cil managed
    {
        .maxstack 8
        L_0001: ldstr ""
        L_0006: newobj instance void [mscorlib]System.Guid::.ctor(string)
        L_000b: stsfld valuetype [mscorlib]System.Guid Test::field
        L_0010: ret     
    }

    .method private hidebysig static void ParameterisedCtorAssignToLocal() cil managed
    {
        .maxstack 2
        .locals init ([0] valuetype [mscorlib]System.Guid guid)    
        L_0001: ldloca.s guid    
        L_0003: ldstr ""    
        L_0008: call instance void [mscorlib]System.Guid::.ctor(string)    
        // Removed ToString() call
        L_001c: ret
    }

    .method private hidebysig static void ParameterisedCtorCallMethod() cil  managed    
    {   
        .maxstack 8
        L_0001: ldstr ""
        L_0006: newobj instance void [mscorlib]System.Guid::.ctor(string)
        L_000b: call void Test::MethodTakingGuid(valuetype [mscorlib]System.Guid)
        L_0011: ret     
    }

    .method private hidebysig static void ParameterlessCtorAssignToField() cil managed
    {
        .maxstack 8
        L_0001: ldsflda valuetype [mscorlib]System.Guid Test::field
        L_0006: initobj [mscorlib]System.Guid
        L_000c: ret 
    }

    .method private hidebysig static void ParameterlessCtorAssignToLocal() cil managed
    {
        .maxstack 1
        .locals init ([0] valuetype [mscorlib]System.Guid guid)
        L_0001: ldloca.s guid
        L_0003: initobj [mscorlib]System.Guid
        // Removed ToString() call
        L_0017: ret 
    }

    .method private hidebysig static void ParameterlessCtorCallMethod() cil managed
    {
        .maxstack 1
        .locals init ([0] valuetype [mscorlib]System.Guid guid)    
        L_0001: ldloca.s guid
        L_0003: initobj [mscorlib]System.Guid
        L_0009: ldloc.0 
        L_000a: call void Test::MethodTakingGuid(valuetype [mscorlib]System.Guid)
        L_0010: ret 
    }

    .field private static valuetype [mscorlib]System.Guid field
}

如您所见，有许多不同的指令用于调用构造函数:

newobj :分配堆栈上的值，调用参数化构造函数。用于中间值，例如用于分配给字段或用作方法参数。

call instance :使用已经分配的存储位置(无论是否在堆栈上)。这在上面的代码中用于分配给局部变量。如果使用多个 new 多次为同一个局部变量赋值调用，它只是在旧值的顶部初始化数据 - 它不会每次分配更多的堆栈空间。

initobj :使用已分配的存储位置并仅删除数据。这用于我们所有的无参数构造函数调用，包括那些分配给局部变量的调用。对于方法调用，有效地引入了一个中间局部变量，其值被 initobj 删除。 .

我希望这表明这个话题有多么复杂，同时也能说明一点。在某些概念上，每次调用 new在堆栈上分配空间 - 但正如我们所见，即使在 IL 级别，这也不是真正发生的事情。我想强调一个特殊的案例。采取这个方法:

void HowManyStackAllocations()
{
    Guid guid = new Guid();
    // [...] Use guid
    guid = new Guid(someBytes);
    // [...] Use guid
    guid = new Guid(someString);
    // [...] Use guid
}

“逻辑上”有 4 个堆栈分配 - 一个用于变量，一个用于三个中的每一个 new调用 - 但实际上(对于该特定代码)堆栈仅分配一次，然后重用相同的存储位置。

编辑:要清楚，这仅在某些情况下是正确的......特别是 guid 的值如果 Guid 将不可见构造函数抛出异常，这就是 C# 编译器能够重用相同堆栈槽的原因。参见 Eric Lippert 的 blog post on value type construction有关更多详细信息以及不适用的情况。

我在写这个答案时学到了很多东西 - 如果有任何不清楚的地方，请要求澄清!