bash - 如何在 awk 脚本中使用 shell 变量？

Question

我找到了一些将外部 shell 变量传递给 awk 的方法。脚本，但我对 ' 感到困惑和 " .

首先，我尝试了一个 shell 脚本:

$ v=123test
$ echo $v
123test
$ echo "$v"
123test

然后尝试了awk:

$ awk 'BEGIN{print "'$v'"}'
$ 123test
$ awk 'BEGIN{print '"$v"'}'
$ 123

为什么有区别？

最后我尝试了这个:

$ awk 'BEGIN{print " '$v' "}'
$  123test
$ awk 'BEGIN{print ' "$v" '}'
awk: cmd. line:1: BEGIN{print
awk: cmd. line:1:             ^ unexpected newline or end of string 

我对此感到困惑。

Answer 1

#Getting shell variables into awk may be done in several ways. Some are better than others. This should cover most of them. If you have a comment, please leave below.                                                                                    v1.5

使用 -v (最好的方式，最便携)
使用 -v选项:(P.S. 在 -v 之后使用一个空格，否则它的便携性会降低。例如，awk -v var= 不是 awk -vvar= )

variable="line one\nline two"
awk -v var="$variable" 'BEGIN {print var}'
line one
line two

这应该与大多数 awk 兼容，并且该变量在 BEGIN 中可用也阻止:
如果您有多个变量:

awk -v a="$var1" -v b="$var2" 'BEGIN {print a,b}'

警告 .正如 Ed Morton 所写，转义序列将被解释为 \t成为真正的tab而不是 \t如果那是您要搜索的内容。可以使用ENVIRON[]解决或通过 ARGV[] 访问它
PS 如果你喜欢三个竖线作为分隔符||| ，无法转义，所以使用-F"[|][|][|]"

Example on getting data from a program/function inn to awk (here date is used)

awk -v time="$(date +"%F %H:%M" -d '-1 minute')" 'BEGIN {print time}'

Example of testing the contents of a shell variable as a regexp:

awk -v var="$variable" '$0 ~ var{print "found it"}'

代码块后的变量
这里我们得到 awk 之后的变量代码。只要您不需要 BEGIN 中的变量，这将正常工作。堵塞:

variable="line one\nline two"
echo "input data" | awk '{print var}' var="${variable}"
or
awk '{print var}' var="${variable}" file

添加多个变量:

awk '{print a,b,$0}' a="$var1" b="$var2" file

这样我们也可以设置不同的字段分隔符FS对于每个文件。

awk 'some code' FS=',' file1.txt FS=';' file2.ext

代码块后的变量对 BEGIN 不起作用 block :

echo "input data" | awk 'BEGIN {print var}' var="${variable}"
这里字符串
变量也可以添加到 awk使用 here-string来自支持它们的 shell(包括 Bash):

awk '{print $0}' <<< "$variable"
test

这与以下内容相同:

printf '%s' "$variable" | awk '{print $0}'

附言这将变量视为文件输入。
ENVIRON输入
正如 TrueY 所写，您可以使用 ENVIRON打印 环境变量 .
在运行 AWK 之前设置一个变量，你可以像这样打印出来:

X=MyVar
awk 'BEGIN{print ENVIRON["X"],ENVIRON["SHELL"]}'
MyVar /bin/bash

ARGV输入
正如 Steven Penny 所写，您可以使用 ARGV将数据放入 awk:

v="my data"
awk 'BEGIN {print ARGV[1]}' "$v"
my data

要将数据放入代码本身，而不仅仅是 BEGIN:

v="my data"
echo "test" | awk 'BEGIN{var=ARGV[1];ARGV[1]=""} {print var, $0}' "$v"
my data test

代码中的变量:谨慎使用
您可以在 awk 中使用变量代码，但它很乱且难以阅读，并且为 Charles Duffy指出，这个版本也可能是代码注入(inject)的受害者。如果有人在变量中添加了不好的东西，它将作为 awk 的一部分执行。代码。
这通过在代码中提取变量来工作，因此它成为它的一部分。
如果你想做一个 awk使用变量动态变化，你可以这样做，但不要将它用于普通变量。

variable="line one\nline two"
awk 'BEGIN {print "'"$variable"'"}'
line one
line two

下面是一个代码注入(inject)的例子:

variable='line one\nline two" ; for (i=1;i<=1000;++i) print i"'
awk 'BEGIN {print "'"$variable"'"}'
line one
line two
1
2
3
.
.
1000

您可以向 awk 添加大量命令这边走。甚至使用无效命令使其崩溃。
但是，这种方法的一个有效用途是当您想要将符号传递给 awk 以应用于某些输入时，例如一个简单的计算器:

$ calc() { awk -v x="$1" -v z="$3" 'BEGIN{ print x '"$2"' z }'; }

$ calc 2.7 '+' 3.4
6.1

$ calc 2.7 '*' 3.4
9.18

没有办法使用填充了 shell 变量值的 awk 变量来做到这一点，您需要在 awk 解释之前扩展 shell 变量以成为 awk 脚本文本的一部分。

额外信息:
双引号的使用
双引号变量 "$variable" 总是好的
如果没有，多行将添加为长单行。
例子:

var="Line one
This is line two"

echo $var
Line one This is line two

echo "$var"
Line one
This is line two

没有双引号可能会出现的其他错误:

variable="line one\nline two"
awk -v var=$variable 'BEGIN {print var}'
awk: cmd. line:1: one\nline
awk: cmd. line:1:    ^ backslash not last character on line
awk: cmd. line:1: one\nline
awk: cmd. line:1:    ^ syntax error

并且使用单引号，它不会扩展变量的值:

awk -v var='$variable' 'BEGIN {print var}'
$variable

有关 AWK 和变量的更多信息
Read this faq .