我正在开发一个 C 程序,该程序调用一个汇编函数,并传递一个数组作为参数。
在汇编代码(对于 8086)中,我能够获取内存中数组的地址并将该地址保存在 ES:BX
中,但之后我需要将值复制到数组中BARCODE
但我找不到任何方法来实现这一点。
我的代码看起来像这样:
代码:
unsigned char computeControlDigit(char* barCodeASCII);
int main( void ){
char barCodeStr[14]
unsigned char controlDigitCheck;
controlDigitCheck = computeControlDigit(barCodeStr);
}
汇编代码:
_DATA SEGMENT WORD PUBLIC 'DATA'
BARCODE DB 13 DUP(?)
_DATA ENDS
PUBLIC _computeControlDigit
_computeControlDigit PROC FAR
PUSH BP
MOV BP, SP
PUSH ES
LES BX, [BP+6]
; code to copy from memory to
; array and code of operations on the array
POP ES
POP BP
RET
_computeControlDigit ENDP
_TEXT ENDS
END
非常欢迎任何帮助。
最佳答案
在大内存模型中,所有数据和代码都非常远,必须通过适当的段进行引用。在下面的代码中,我将指向源字符串 barcodestr
的指针加载到 DS:SI 中,将 BARCODE
加载到 ES:DI 中>。然后,我使用 LODSB 从 barcodestr
数组中读取字符。并将其保存到 BARCODE
中 STOSB
。当到达 NUL 终止符时,复制完成。
假设方向标志 (DF) 设置为 0(向前移动):
STOSB
与1类似:mov [ES:DI], al lea di, [DI + 1] ; Increment DI by 1 without altering flags
LODSB
与1类似:mov al, [DS:SI] lea si, [SI + 1] ; Increment SI by 1 without altering flags
我不知道您是否使用 MASM 还是 TASM 作为汇编器,因此我提供了两者的版本。仅复制 NUL 终止字符串的示例 TASM 代码如下:
.MODEL LARGE, C
PUBLIC computeControlDigit
_DATA SEGMENT WORD PUBLIC 'DATA'
BARCODE DB 13 DUP(?)
_DATA ENDS
_TEXT SEGMENT WORD PUBLIC 'TEXT'
ASSUME DS:_DATA, CS:_TEXT
computeControlDigit PROC C FAR
ARG %%barcodestr:DWORD ; barcodestr is a FAR pointer (DWORD)
USES DS, SI, DI ; Save non-volatile registers
MOV AX, SEG BARCODE ; Get segment and offset (FAR PTR) of BARCODE
MOV ES, AX ; into ES:DI
MOV DI, OFFSET BARCODE
LDS SI, %%barcodestr ; Load barcodestr FAR pointer into DS:SI
JMP %%GETCHAR ; Get next character
%%NEXTCHAR:
STOSB ; Store character to ES:DI (BARCODE), DI++
%%GETCHAR:
LODSB ; Read character from DS:SI (barcodestr), SI++
TEST AL, AL ; Is it a NUL terminator?
JNZ %%NEXTCHAR ; If not go back and get next character
%%ENDLOOP:
STOSB ; Store NUL terminator at end of BARCODE
RET
computeControlDigit ENDP
_TEXT ENDS
END
当然,您可以选择进行任何处理。我只是直接复制了数据作为示例。
如果使用 MASM,您可能需要使用稍微不同的语法:
.MODEL LARGE, C
PUBLIC computeControlDigit
_DATA SEGMENT WORD PUBLIC 'DATA'
BARCODE DB 13 DUP(?)
_DATA ENDS
_TEXT SEGMENT WORD PUBLIC 'TEXT'
ASSUME DS:_DATA, CS:_TEXT
computeControlDigit PROC FAR C USES DS SI DI barcodestr:DWORD
; DS, SI, DI are saved as they are non-volatile registers
; barcodestr is a FAR pointer (DWORD)
MOV AX, SEG BARCODE ; Get segment and offset (FAR PTR) of BARCODE
MOV ES, AX ; into ES:DI
MOV DI, OFFSET BARCODE
LDS SI, barcodestr ; Load barcodestr FAR pointer into DS:SI
JMP GETCHAR ; Get next character
NEXTCHAR:
STOSB ; Store character to ES:DI (BARCODE), DI++
GETCHAR:
LODSB ; Read character from DS:SI (barcodestr), SI++
TEST AL, AL ; Is it a NUL terminator?
JNZ NEXTCHAR ; If not go back and get next character
STOSB ; Store NUL terminator at end of BARCODE
RET
computeControlDigit ENDP
_TEXT ENDS
END
不使用特殊汇编程序指令的原始版本对您来说可能看起来更自然:
PUBLIC _computeControlDigit
_DATA SEGMENT WORD PUBLIC USE16 'DATA'
BARCODE:
DB 13 DUP(?)
_DATA ENDS
_TEXT SEGMENT WORD PUBLIC USE16 'TEXT'
ASSUME CS:_TEXT, DS:_DATA
_computeControlDigit:
push bp
mov bp,sp
push ds
push si
push di
mov ax,seg BARCODE
mov es,ax
mov di,offset BARCODE
lds si,dword ptr 6[bp]
jmp GETCHAR
NEXTCHAR:
stosb
GETCHAR:
lodsb
test al,al
jne NEXTCHAR
stosb
pop di
pop si
pop ds
pop bp
retf
_TEXT ENDS
END
脚注
- 1
LODSB
和STOSB
与所示的等效代码相似,但LODSB 除外
和STOSB
各自作为一条指令完整执行。
关于c - 如何将内存数据从指针复制到数组 ASSEMBLY 8086,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/55386623/