这是一个仅由 if 组成的冒泡排序。这是我在 Lisp 中的第一个代码，这就是为什么我没有使用函数“loop”或“DO”，因为我不知道如何使用它们。
(defun bubble()
((let (array (make-array '(4))))
(setf (aref array 0) 7)
(setf (aref array 1) 2)
(setf (aref array 2) 4)
(setf (aref array 3) 5))
(setf i 0)
(defun c1 (IF (<= i (- n 1))
(progn (setq j 1)
(defun c2 (j) (IF (<= j (- n i))
(progn(IF (> (aref array j) (aref array (+ j 1)))
(progn (setq aux (aref array (+ j 1)))
(setq (aref array (+ j 1)) (aref array j))
(setq (aref array j) aux)
(c2 (setq j (+ j 1))))
(c2 (setq j (+ j 1)))
);if
);progn
(c1 (setq i (+ i 1)))
);if
);c2
);progn
array();
)
);c1
);bubble
问题是它不打印数组，它只打印单词 BUBBLE。有人在之前的帖子中说过 defun 总是返回函数的名称，但是没有 defun 我怎么能创建一个名为 bubble 的函数返回一个数组？？？
最佳答案
我认为我们必须把它分开一点。
如果你使用适当的缩进，你不需要注释你的括号，这使得整体编码体验更好:
(defun bubble ()
((let (array (make-array '(4))))
(setf (aref array 0) 7)
(setf (aref array 1) 2)
(setf (aref array 2) 4)
(setf (aref array 3) 5))
(setf i 0)
(defun c1 (IF (<= i (- n 1))
(progn (setq j 1)
(defun c2 (j) (if (<= j (- n i))
(progn (if (> (aref array j) (aref array (+ j 1)))
(progn (setq aux (aref array (+ j 1)))
(setq (aref array (+ j 1)) (aref array j))
(setq (aref array j) aux)
(c2 (setq j (+ j 1))))
(c2 (setq j (+ j 1)))))
(c1 (setq i (+ i 1))))))
array
())))
现在，有一些语法错误。我不知道如何在没有警告的情况下进行编译。
你的 defun c1 ...表单缺少参数列表。
(defun bubble ()
((let (array (make-array '(4))))
(setf (aref array 0) 7)
(setf (aref array 1) 2)
(setf (aref array 2) 4)
(setf (aref array 3) 5))
(setf i 0)
(defun c1 ()
(if (<= i (- n 1))
(progn (setq j 1)
(defun c2 (j) (if (<= j (- n i))
(progn (if (> (aref array j) (aref array (+ j 1)))
(progn (setq aux (aref array (+ j 1)))
(setq (aref array (+ j 1)) (aref array j))
(setq (aref array j) aux)
(c2 (setq j (+ j 1))))
(c2 (setq j (+ j 1)))))
(c1 (setq i (+ i 1))))))
array
())))
你的 let形式完全困惑。 Let可以创建多个绑定(bind)，因此您需要将绑定(bind)包装在一个列表中。 let form 也不是有效的运算符。它的主体需要在表单内部。绑定(bind)只有主体的范围。
(defun bubble ()
(let ((array (make-array '(4))))
(setf (aref array 0) 7)
(setf (aref array 1) 2)
(setf (aref array 2) 4)
(setf (aref array 3) 5)
(setf i 0)
(defun c1 ()
(if (<= i (- n 1))
(progn (setq j 1)
(defun c2 (j) (if (<= j (- n i))
(progn (if (> (aref array j) (aref array (+ j 1)))
(progn (setq aux (aref array (+ j 1)))
(setq (aref array (+ j 1)) (aref array j))
(setq (aref array j) aux)
(c2 (setq j (+ j 1))))
(c2 (setq j (+ j 1)))))
(c1 (setq i (+ i 1))))))
array
()))))
你的 if表格 c1有四个参数，但是 if只需要三个。我将删除 ()最后，这看起来很荒谬:
(defun bubble ()
(let ((array (make-array '(4))))
(setf (aref array 0) 7)
(setf (aref array 1) 2)
(setf (aref array 2) 4)
(setf (aref array 3) 5)
(setf i 0)
(defun c1 ()
(if (<= i (- n 1))
(progn (setq j 1)
(defun c2 (j) (if (<= j (- n i))
(progn (if (> (aref array j) (aref array (+ j 1)))
(progn (setq aux (aref array (+ j 1)))
(setq (aref array (+ j 1)) (aref array j))
(setq (aref array j) aux)
(c2 (setq j (+ j 1))))
(c2 (setq j (+ j 1)))))
(c1 (setq i (+ i 1))))))
array))))
不要试图嵌套defun秒。这不像你想象的那样有效。它仍然会定义全局函数定义，只是在不同的时间。对于局部函数定义，使用 labels或 flet :
(defun bubble ()
(let ((array (make-array '(4))))
(setf (aref array 0) 7)
(setf (aref array 1) 2)
(setf (aref array 2) 4)
(setf (aref array 3) 5)
(setf i 0)
(labels ((c1 ()
(if (<= i (- n 1))
(progn (setq j 1)
(labels ((c2 (j)
(if (<= j (- n i))
(progn (if (> (aref array j) (aref array (+ j 1)))
(progn (setq aux (aref array (+ j 1)))
(setq (aref array (+ j 1)) (aref array j))
(setq (aref array j) aux)
(c2 (setq j (+ j 1))))
(c2 (setq j (+ j 1)))))
(c1 (setq i (+ i 1))))))))
array))))))
让我们缩短数组初始化时间:
(defun bubble ()
(let ((array (copy-seq #(7 2 4 5))))
(setf i 0)
(labels ((c1 ()
(if (<= i (- n 1))
(progn (setq j 1)
(labels ((c2 (j)
(if (<= j (- n i))
(progn (if (> (aref array j) (aref array (+ j 1)))
(progn (setq aux (aref array (+ j 1)))
(setq (aref array (+ j 1)) (aref array j))
(setq (aref array j) aux)
(c2 (setq j (+ j 1))))
(c2 (setq j (+ j 1)))))
(c1 (setq i (+ i 1))))))))
array))))))
Aux , n , j , 和 i没有定义。通过设置它们，您可以创建新的全局变量，这些变量可能特殊，也可能不特殊。不要这样。首先使用 let 为它们创建绑定(bind).此外，您不需要 progn对于单个表单。
(defun bubble ()
(let ((array (copy-seq #(7 2 4 5)))
(n 4)
(i 0)
(aux 0))
(labels ((c1 ()
(if (<= i (- n 1))
(let ((j 1))
(labels ((c2 (j)
(if (<= j (- n i))
(if (> (aref array j) (aref array (+ j 1)))
(progn (setq aux (aref array (+ j 1)))
(setq (aref array (+ j 1)) (aref array j))
(setq (aref array j) aux)
(c2 (setq j (+ j 1))))
(c2 (setq j (+ j 1))))
(c1 (setq i (+ i 1))))))))
array))))))
我认为我们现在已经涵盖了句法问题。让我们来简化一下。
交换两个(或更多)位置可以用 rotatef 完成，您不需要为此创建临时变量。有一个函数 1+为某物加 1。
(defun bubble ()
(let ((array (copy-seq #(7 2 4 5)))
(n 4)
(i 0))
(labels ((c1 ()
(if (<= i (- n 1))
(let ((j 1))
(labels ((c2 (j)
(if (<= j (- n i))
(if (> (aref array j) (aref array (1+ j)))
(progn (rotatef (aref array j)
(aref array (1+ j)))
(c2 (setq j (1+ j))))
(c2 (setq j (1+ j))))
(c1 (setq i (1+ i))))))))
array))))))
使用incf 增加变量的值并将其存储回该变量:
(defun bubble ()
(let ((array (copy-seq #(7 2 4 5)))
(n 4)
(i 0))
(labels ((c1 ()
(if (<= i (- n 1))
(let ((j 1))
(labels ((c2 (j)
(if (<= j (- n i))
(if (> (aref array j) (aref array (1+ j)))
(progn (rotatef (aref array j)
(aref array (1+ j)))
(c2 (incf j)))
(c2 (incf j)))
(c1 (incf i)))))))
array))))))
而不是使用 <= 进行测试针对小于整数的 1，使用 < 进行测试针对整数本身:
(defun bubble ()
(let ((array (copy-seq #(7 2 4 5)))
(n 4)
(i 0))
(labels ((c1 ()
(if (< i n)
(let ((j 1))
(labels ((c2 (j)
(if (< j n)
(if (> (aref array j) (aref array (1+ j)))
(progn (rotatef (aref array j)
(aref array (1+ j)))
(c2 (incf j)))
(c2 (incf j)))
(c1 (incf i)))))))
array))))))
而不是重复对 c2 的内部调用，把你想做的事情移到一级之前。
(defun bubble ()
(let ((array (copy-seq #(7 2 4 5)))
(n 4)
(i 0))
(labels ((c1 ()
(if (< i n)
(let ((j 1))
(labels ((c2 (j)
(if (< j n)
(progn
(when (> (aref array j)
(aref array (1+ j)))
(rotatef (aref array j)
(aref array (1+ j))))
(c2 (incf j)))
(c1 (incf i)))))))
array))))))
您的内部函数永远不会被调用。让我们解决这个问题，并清理参数处理:
(defun bubble ()
(let ((array (copy-seq #(7 2 4 5)))
(n 4))
(labels ((c1 (i)
(if (< i n)
(labels ((c2 (j)
(if (< j n)
(progn
(when (> (aref array j)
(aref array (1+ j)))
(rotatef (aref array j)
(aref array (1+ j))))
(c2 (1+ j)))
(c1 (1+ i)))))
(c2 1))
array)))
(c1 0))))
J不应从 1 运行，而应从 i 运行. I和 j应该只运行到低于 (1- n) ，因为 (1+ j)必须是有效的数组索引。
(defun bubble ()
(let ((array (copy-seq #(7 2 4 5)))
(n 4))
(labels ((c1 (i)
(if (< i (1- n))
(labels ((c2 (j)
(if (< j (1- n))
(progn
(when (> (aref array j)
(aref array (1+ j)))
(rotatef (aref array j)
(aref array (1+ j))))
(c2 (1+ j)))
(c1 (1+ i)))))
(c2 i))
array)))
(c1 0))))
我认为这现在可以工作，只要数组长度小于您的堆栈限制。
不在函数内部定义要排序的数组，而是将其作为参数传递是有意义的。这样，您实际上可以使用该函数对任何数组(实际上是任何向量，即一维数组)进行排序。 N是该向量的长度。
(defun bubble (vector)
(let ((n (length vector)))
(labels ((c1 (i)
(if (< i (1- n))
(labels ((c2 (j)
(if (< j (1- n))
(progn
(when (> (aref vector j)
(aref vector (1+ j)))
(rotatef (aref vector j)
(aref vector (1+ j))))
(c2 (1+ j)))
(c1 (1+ i)))))
(c2 i))
vector)))
(c1 0))))
;;; For example, call with (bubble (copy-seq #(7 2 4 5))). It should return #(2 4 5 7).
为了不修改作为参数传递的向量，请使用 copy-seq在排序之前制作副本。让函数修改其参数总是令人惊讶。我们也不会遇到修改文字数据的潜在问题。
(defun bubble (unsorted-vector)
(let ((vector (copy-seq unsorted-vector))
(n (length unsorted-vector)))
(labels ((c1 (i)
(if (< i (1- n))
(labels ((c2 (j)
(if (< j (1- n))
(progn
(when (> (aref vector j)
(aref vector (1+ j)))
(rotatef (aref vector j)
(aref vector (1+ j))))
(c2 (1+ j)))
(c1 (1+ i)))))
(c2 i))
vector)))
(c1 0))))
;;; For example, call with (bubble #(7 2 4 5)). It should return #(2 4 5 7).
为了消除堆栈限制，让我们将其转换为循环。
(defun bubble (unsorted-vector)
(let ((vector (copy-seq unsorted-vector))
(n (length unsorted-vector)))
(loop :for i :below (1- n)
:do (loop :for j :from i :below (1- n)
:do (when (> (aref vector j)
(aref vector (1+ j)))
(rotatef (aref vector j)
(aref vector (1+ j))))))
vector))
关于lisp - 冒泡排序不返回排序数组，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/26836528/