lisp - 谁能给我一些关于这个问题(家谱)的提示？

Question

它来 self 的家庭作业。有家谱

                             a  +  b
                         /   |    |   \ 
                        c+u  d+c  e+w  f
                     / | \        / \
                 m+x  n+y  o      p  q
                  |
                  r

a和b是最旧的。每个已婚人士的第二个人都不是原始家庭的一部分。 现在我需要编写配偶、 sibling 、子女、孙子女、 parent 和祖 parent 函数。

我写的 list 如下: ( (爸爸妈妈) chlid1 child2 child3)

(((a b) c d e f) ((c u) m n o) ((d v) nil) ((e w) p q) (f nil) ((m x) r) ((n y) nil) (o nil) (p nil) (q nil)  )

我的兄弟函数有一些问题，这是我的代码。

(defun sibling  (arglst lst)  
 (cond
        ((eql 
             arglst (cdr (car lst))) 
                 (rest (cdr lst))
         )
   (T (sibling (rest lst) arglst))

)

我知道这是错误的，但我不知道如何修改它..我还需要一些其他功能的帮助。希望能从你们那里得到一些提示。

Answer 1

由于这是作业，我不会给出完整的解决方案，但这应该足以让您解决其余的问题:

(defparameter *family* '(((a b) c d e f)
                         ((c u) m n o)
                         ((d v) nil)
                         ((e w) p q)
                         (f nil)
                         ((m x) r)
                         ((n y) nil)
                         (o nil)
                         (p nil)
                         (q nil)))

(defun siblings (person family)
  "Return a list of PERSON's siblings."
  (remove person (cdr (find person family :key #'cdr :test #'member))))

(defun siblingsp (person1 person2 family)
  "Are PERSON1 and PERSON2 siblings?"
  (find person2 (siblings person1 family)))

(defun parents (person family)
  "Return a list of PERSON's parents."
  (car (find person family :key #'cdr :test #'member)))

(defun parentp (parent child family)
  "Is PARENT a parent of CHILD?"
  (find parent (parents child family)))

试一试:

CL-USER> (siblings 'p *family*)
(Q)
CL-USER> (siblingsp 'q 'p *family*)
P
CL-USER> (parents 'p *family*)
(E W)

现在，例如要查找祖 parent ，您只需了解祖 parent 是什么:​​(列表) parent 双方的 parent 。然后，问问自己这对孙子们来说怎么样。最后，鉴于此示例，spouse 函数应该相当简单。