我们一直在我的 AI 类(class)中使用 Lisp。我收到的作业涉及搜索和生成树状结构。对于每项作业,我最终都写了类似这样的内容:
(defun initial-state ()
(list
0 ; score
nil ; children
0 ; value
0)) ; something else
并围绕这些“状态”构建我的函数,这些“状态”实际上只是具有一些松散定义结构的嵌套列表。
为了使结构更严格,我尝试编写访问器,例如:
(defun state-score ( state )
(nth 2 state))
这适用于读取值(这应该是我在一个漂亮的函数世界中需要做的全部事情。但是,随着时间的推移,我开始疯狂地破解,有时我想要一个可变的结构)。我似乎无法设置返回的...东西(位置?值?指针?)。
我收到类似这样的错误:
(setf (state-score *state*) 10)
有时我似乎更幸运地将访问器/修改器写成宏:
(defmacro state-score ( state )
`(nth 2 ,state))
但是我不知道为什么这应该是一个宏,所以我当然不应该把它写成一个宏(除了有时它可以工作。巧合编程是不好的)。
构建此类结构的合适策略是什么?
更重要的是,我在哪里可以了解这里发生了什么(哪些操作以何种方式影响内存)?
最佳答案
将 CLOS 用于数据结构
解决这个问题的最佳方法是快速学习 CLOS 的基础知识。
(defclass state ()
((score :accessor state-score :initform 0)
(children :accessor state-children :initform nil)
(value :accessor state-value :initform 0)))
(defun make-initial-state ()
(make-instance 'state))
(defparameter *state* (make-initial-state))
(setf (state-score *state*) 10)
对于大多数应用程序代码,避免使用结构
对于大多数代码,请避免结构 - 仅在您需要它们并且知道原因时才使用它们。请改用 CLOS 类。
DEFSTRUCT 也适用于列表
如果您真的想使用列表,一种选择是对列表使用 DEFSTRUCT 宏并让它定义所有函数:
(defstruct (state (:type list))
(score 0)
(children nil)
(value 0))
上面,:type 选项告诉 DEFSTRUCT 使用列表而不是结构。
? (defparameter *state* (make-state))
*STATE*
? (setf (state-score *state*) 10)
10
(make-state) 返回包含三个项目的列表。
我们可以编写setter函数
如果你想手写代码,那么你可以写setter函数:
(defun get-my-score (state)
(first state))
(defun (setf get-my-score) (score state)
(setf (first state) score))
上面定义了一个SETF函数。函数名实际上是一个列表。此函数的参数必须首先是新值,然后是要设置的内容。
? (setf *state* (list 0 nil 0))
(0 NIL 0)
? (setf (get-my-score *state*) 10)
10
? *state*
(10 NIL 0)
Common Lisp HyperSpec 定义了位置是什么以及如何使用它们。我猜想这不是最好的学习来源,可能最好在一些介绍 Lisp 的书中对其进行解释。
关于lisp - 我如何通过访问器设置树中的元素?,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/2536036/