c++ - CUDA并行计算加速体积计算

标签 c++ performance cuda

  • 设备:Tesla C2050
  • 操作系统:Windows 7 企业版
  • IDE:VS 2010
  • CUDA:5.0(最新)

第一次在这里提问。我在 CUDA 程序中遇到了一些问题。

我有数百万个四面体，其中一个点位于 (0,0,0)，因此我可以使用以下公式:

获取四面体的体积。

所以，这是代码:

struct Triangle
{
    double x1;
    double y1;
    double z1;
    double x2;
    double y2;
    double z2;
    double x3;
    double y3;
    double z3;
};

以及 CUDA 代码:

__global__ void getResult(double *d_volume ,Triangle *d_triangles, Origin *d_point)
{
    extern __shared__ Triangle s_data[];
    int tid = threadIdx.x;
    int i =  blockDim.x * blockIdx.x + threadIdx.x;
    s_data[tid] = d_triangles[i];
    __syncthreads();
    d_volume[i] =s_data[tid].x1 * s_data[tid].y2 * s_data[tid].z3 + \
                s_data[tid].y1 * s_data[tid].z2 * s_data[tid].x3 + \
                s_data[tid].x2 * s_data[tid].y3 * s_data[tid].z1 - \
                s_data[tid].x3 * s_data[tid].y2 * s_data[tid].z1 - \
                s_data[tid].x2 * s_data[tid].y1 * s_data[tid].z3 - \
                s_data[tid].y3 * s_data[tid].z2 * s_data[tid].x1;
}

我从其他函数中获得了数百万个四面体作为数组。

// Host
Triangle *h_triangles = triangles;
double *h_volume;
// Device
Triangle *d_triangles;
double *d_volume;

// define grid and block size
int numThreadsPerBlock = numTriangles;
int numBlocks = numTrianges / 512;

// Shard memory size
int sharedMemSize = numThreadsPerBlock * sizeof(Triangle);

// allocate host and device memory
size_t memSize_triangles = numBlocks * numThreadsPerBlock * sizeof(Triangle);
size_t memSize_volume = numBlocks * numThreadsPerBlock * sizeof(double);

cudaMalloc( (void **) &d_triangles, memSize_triangles );
cudaMalloc( (void **) &d_volume, memSize_volume );

// Copy host array to device array
cudaMemcpy( d_triangles, h_triangles, memSize_triangles, cudaMemcpyHostToDevice );
cudaMemcpy( d_point, h_point, memSize_point, cudaMemcpyHostToDevice );

// launch kernel
dim3 dimGrid(numBlocks);
dim3 dimBlock(numThreadsPerBlock);

getResult<<< dimGrid, dimBlock, sharedMemSize >>>( d_volume, d_triangles);

// block until the device has completed
cudaThreadSynchronize();

// device to host copy
cudaMemcpy( h_volume, d_volume, memSize_volume, cudaMemcpyDeviceToHost );

// free device memory
cudaFree(d_triangles);
cudaFree(d_volume);

// free host memory
free(h_triangles); 
free(h_volume);

到目前为止，一切正常。但我花了比我想象的更多的时间来获得音量。 我的设备是 Tesla C2050(515Gflops)，比我的 CPU(单核，20.25Gflops)快 20 倍。 但仅加速10倍左右(不包括设备和主机之间复制内存的时间)

我想知道如何使其比 CPU 代码快大约 20 倍(for 循环获取音量。)。

谢谢!

PS:也许cudaMallocPitch()会帮助我，但三角形不是矩阵，我不能使用cudaMemcpy2D()代替cudaMemcpy()来复制内存。谁能帮我解答这个问题吗？

最佳答案

与 CPU 相比，GPU 的峰值性能通常更难获得。原因之一是许多内核受带宽限制而不是计算限制。

因为你的内核的计算复杂度是 O(n)。您可能应该使用带宽指标来计算理论峰值性能，如下所示

1024*1024*64 * sizeof(double) * (9  +   1)     / (144e9    *    8/9)     = 42 ms
#tetrahedron                     #input #output   peak mem bw   ECC cost

另一方面，您的内核可以进一步优化。

  • 谨慎选择 blockDim/gridDim，错误的数字有时会导致 20% 的性能损失。
  • 您可以为每个线程计算多个卷，而不是为每个线程计算一个卷，这将减少线程启动开销。
  • 由于您不在线程之间共享数据，因此可以消除 __syncthreads()。
  • 由于非合并内存访问，结构数组 (AoS) 在 GPU 上通常比数组结构 (SoA) 慢。您还可以尝试更改数据结构。

更新

获得了具有大型 L1 缓存设置和最佳 blockDim/gridDim 选择的新内核。速度快了 15%。这是代码和配置文件结果。我的设备是M2090。

profile result 

#include <stdlib.h>
#include <thrust/transform.h>
#include <thrust/device_vector.h>
#include <thrust/host_vector.h>
#include <iterator>
#include <thrust/inner_product.h>

using namespace thrust::placeholders;

struct Triangle
{
    double x1;
    double y1;
    double z1;
    double x2;
    double y2;
    double z2;
    double x3;
    double y3;
    double z3;
};

__global__ void getResultNoSMem(double *d_volume, Triangle *d_triangles)
{
    int i = blockDim.x * blockIdx.x + threadIdx.x;
    d_volume[i] = d_triangles[i].x1 * d_triangles[i].y2 * d_triangles[i].z3 +
            d_triangles[i].y1 * d_triangles[i].z2 * d_triangles[i].x3 +
            d_triangles[i].x2 * d_triangles[i].y3 * d_triangles[i].z1 -
            d_triangles[i].x3 * d_triangles[i].y2 * d_triangles[i].z1 -
            d_triangles[i].x2 * d_triangles[i].y1 * d_triangles[i].z3 -
            d_triangles[i].y3 * d_triangles[i].z2 * d_triangles[i].x1;
}

__global__ void getResult(double *d_volume, Triangle *d_triangles)
{
    extern __shared__ Triangle s_data[];
    int tid = threadIdx.x;
    int i = blockDim.x * blockIdx.x + threadIdx.x;
    s_data[tid] = d_triangles[i];
//  __syncthreads();
    d_volume[i] = s_data[tid].x1 * s_data[tid].y2 * s_data[tid].z3 +
            s_data[tid].y1 * s_data[tid].z2 * s_data[tid].x3 +
            s_data[tid].x2 * s_data[tid].y3 * s_data[tid].z1 -
            s_data[tid].x3 * s_data[tid].y2 * s_data[tid].z1 -
            s_data[tid].x2 * s_data[tid].y1 * s_data[tid].z3 -
            s_data[tid].y3 * s_data[tid].z2 * s_data[tid].x1;
}

__global__ void getResultOpt(double *d_volume, Triangle *d_triangles, int len)
{
    const int gridSize = blockDim.x * gridDim.x;
    int i = blockDim.x * blockIdx.x + threadIdx.x;

    while (i < len)
    {
        d_volume[i] = d_triangles[i].x1 * d_triangles[i].y2 * d_triangles[i].z3 +
                d_triangles[i].y1 * d_triangles[i].z2 * d_triangles[i].x3 +
                d_triangles[i].x2 * d_triangles[i].y3 * d_triangles[i].z1 -
                d_triangles[i].x3 * d_triangles[i].y2 * d_triangles[i].z1 -
                d_triangles[i].x2 * d_triangles[i].y1 * d_triangles[i].z3 -
                d_triangles[i].y3 * d_triangles[i].z2 * d_triangles[i].x1;
        i += gridSize;
    }
}

int main(void)
{
    const int m = 1024 * 1024;
    thrust::host_vector<Triangle> data(m);
    for (int i = 0; i < m; i++)
    {
        data[i].x1 = (double) rand() / RAND_MAX;
        data[i].y1 = (double) rand() / RAND_MAX;
        data[i].z1 = (double) rand() / RAND_MAX;
        data[i].x2 = (double) rand() / RAND_MAX;
        data[i].y2 = (double) rand() / RAND_MAX;
        data[i].z2 = (double) rand() / RAND_MAX;
        data[i].x3 = (double) rand() / RAND_MAX;
        data[i].y3 = (double) rand() / RAND_MAX;
        data[i].z3 = (double) rand() / RAND_MAX;
    }

    thrust::device_vector<Triangle> triangles = data;
    thrust::device_vector<double> volume(m);
    thrust::device_vector<double> volumeOpt(m);

    Triangle* dTriangles = thrust::raw_pointer_cast(&triangles[0]);
    double* dVolume = thrust::raw_pointer_cast(&volume[0]);
    double* dVolumeOpt = thrust::raw_pointer_cast(&volumeOpt[0]);

    int g;
    int b;

    int threadUpperLimit = 48 * 1024 / sizeof(Triangle);

    //for (b = 32; b <= 1024; b += 32)
    {
        b = 64;
        int gridDim = (m + b - 1) / b;
        getResultNoSMem<<<gridDim, b, 0, 0>>>(dVolume, dTriangles);
    }

    //  for (b = 32; b <= threadUpperLimit; b += 32)
    {
        b = 64;
        int gridDim = (m + b - 1) / b;
        getResult<<<gridDim, b, b * sizeof(Triangle), 0>>>(dVolume, dTriangles);
    }

    //for (g = 32; g <= 512; g += 32)
    //  for (b = 32; b <= 1024; b += 32)
    {
        b = 64;
        g = 64;
        getResultOpt<<<g, b, 0, 0>>>(dVolumeOpt, dTriangles, m);
    }

    //for (g = 32; g <= 512; g += 32)
    //  for (b = 32; b <= 1024; b += 32)
    {
        b = 64;
        g = 512;
        cudaFuncSetCacheConfig(getResultOpt, cudaFuncCachePreferL1);
        getResultOpt<<<g, b, 0, 0>>>(dVolumeOpt, dTriangles, m);
    }

    thrust::device_vector<double> X = volume;
    thrust::device_vector<double> Y = volumeOpt;
    thrust::transform(X.begin(), X.end(), Y.begin(), X.begin(), _1 - _2);
    double result = thrust::inner_product(X.begin(), X.end(), X.begin(), 0.0);

    std::cout << "difference: " << result << std::endl;

    return 0;
}

关于c++ - CUDA并行计算加速体积计算，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/18480975/

上一篇：c++ - 我可以使用函数符号 operator#() 来调用内置类型的运算符吗？

下一篇：C++ Unordered_map 与自定义类

相关文章：

c++ - 从链表c++中删除最后一个节点

c# - 为什么在循环内使用 List.IndexOf(List.Where()) 时会出现性能问题？

java - 更快的 CPU 不会提高性能，而增加线程数会。业内最好的共享内存计算机？

c++ - 能否将一个类简单地传递给 CUDA 内核以进行并行评估？

cuda - 如何获取CUDA版本？

c++ - 如何使数组不重复？

c++ - 如何知道是否有任何可供安装的 Windows 操作系统更新？

c++ - 在 C++ 中将 Mutex 和 lock_guard 与 vector 一起使用

java - 安全模式下的 MongoDB 性能

c++ - 带有 CUDA 的 Visual Studio 2017 无法打开包含文件 'cuda.h'

©2024 IT工具网  联系我们