linux - 如何在 Linux 上更改包含特定字符串的所有目录/文件的名称

Question

我有一个目录，我想将其下的所有目录名称和文件更改为不同的名称。比如我的目录结构是

./mydir_ABC/
./mydir_ABC/myfile_ABC.txt
./mydir_ABC/otherdir_ABC/

我想做个例子

./mydir_DEF/
./mydir_DEF/myfile_DEF.txt
./mydir_DEF/otherdir_DEF/

我正在使用

find . -type 'f' -name '*ABC*'
find . -type 'd' -name '*ABC*'

获取名称中包含我的字符串的所有相关目录和文件的列表。我如何将它传递给另一个将实际更改目录名和文件名的命令？ (如果文件或目录已经存在，我希望它能够覆盖。)

Answer 1

查找 rename(1) 命令。它有一些不同的变体，但它们都支持基于某种正则表达式的某种重命名。我使用的版本(基于 Perl“Camel Book”第一版的代码)将用作:

rename 's%ABC%DEF%g' ...

或者，对于您的示例:

find . -print0 | xargs -0 rename s/ABC/DEF/g

或者，为了避免在遍历目录结构时路径名发生变化的问题，首先执行目录名，然后是文件(如问题中所示):

find . -type d -print0 | xargs -0 rename s/ABC/DEF/g
find . -type f -print0 | xargs -0 rename s/ABC/DEF/g

重命名目录时仍然存在问题(因为一旦将 ./ABC 重命名为 ./DEF，就无法再重命名 ./ABC/subABC/ 到 ./DEF/subDEF 因为目录现在是 ./DEF/subABC).

rename 的其他版本具有不同的语法 - 请查看您的手册页。

---

这是 rename 的基于 Perl 的版本，源自 Perl 的“ Camel 之书”第一版；我在版本控制下的第一个版本的日期是 1992-01-05。今天的更改更新了 shebang 行(使用 env，删除了 -w 因为它不可靠，并添加了 use warnings; 以补偿没有 -w).之前的变化是 2008 年、1998 年、1996 年和 1992 年；在过去的 19 年里，它没有太大变化。

#!/usr/bin/env perl
#
# @(#)$Id: rename.pl,v 1.8 2011/06/03 22:30:22 jleffler Exp $
#
# Rename files using a Perl substitute or transliterate command

use strict;
use warnings;
use Getopt::Std;

my(%opts);
my($usage) = "Usage: $0 [-fnxV] perlexpr [filenames]\n";
my($force) = 0;
my($noexc) = 0;
my($trace) = 0;

die $usage unless getopts('fnxV', \%opts);

if ($opts{V})
{
    printf "%s\n", q'RENAME Version $Revision: 1.8 $ ($Date: 2011/06/03 22:30:22 $)';
    exit 0;
}
$force = 1 if ($opts{f});
$noexc = 1 if ($opts{n});
$trace = 1 if ($opts{x});

my($op) = shift;
die $usage unless defined $op;

if (!@ARGV) {
    @ARGV = <STDIN>;
    chop(@ARGV);
}

for (@ARGV)
{
    if (-e $_ || -l $_)
    {
        my($was) = $_;
        eval $op;
        die $@ if $@;
        next if ($was eq $_);
        if ($force == 0 && -f $_)
        {
            print STDERR "rename failed: $was - $_ exists\n";
        }
        else
        {
            print "+ $was --> $_\n" if $trace;
            print STDERR "rename failed: $was - $!\n"
                unless ($noexc || rename($was, $_));
        }
    }
    else
    {
        print STDERR "$_ - $!\n";
    }
}