我目前有一个通过 ASP .NET 前端 Access 的 Microsoft Access 数据库。我正在尝试向表中添加一行,但这似乎不起作用,我使用的代码如下所示。
Sub prcChoose()
Dim sql As String
Dim da As New OleDbDataAdapter
Dim conn As New OleDbConnection
Dim comm As New OleDbCommand
Dim cb As New OleDbCommandBuilder(da)
ds = New DataSet
conn = New OleDbConnection(ConfigurationManager.ConnectionStrings("dbConnection").ConnectionString)
sql = "SELECT * FROM ParentPreference"
conn.Open()
da = New OleDbDataAdapter(sql, conn)
da.Fill(ds, "Choice")
Dim NewRow As Data.DataRow = ds.Tables("Choice").NewRow()
NewRow.Item(0) = txtUser.Text
NewRow.Item(1) = dropdown.SelectedValue
ds.Tables("Choice").Rows.Add(NewRow)
***da.UpdateCommand = cb.GetUpdateCommand()***
da.Update(ds, "Choice")
End Sub
我会收到不同的错误消息,具体取决于是否包含 3 个星号所包含的行。没有它,我会收到“当传递带有新行的 DataRow 集合时,更新需要有效的 InsertCommand。”,而有了它,我会收到“需要初始化 DataAdapter.SelectCommand 属性。”我花了几个小时试图弄清楚哪里出了问题,但我没有取得任何成功。
提前致谢!
编辑:根据下面 Casey 的建议,我添加了以下代码行:
da.InsertCommand = cb.GetInsertCommand
da.DeleteCommand = cb.GetDeleteCommand
我在上面用星号括起来的代码下面添加了这些行。但我仍然收到相同的错误消息。 DataAdapter.SelectCommand 属性需要初始化。此错误发生在以下行
da.InsertCommand = cb.GetInsertCommand
最佳答案
由于我目前无法进入 Visual Studio 检查您的代码,因此从内存中进行拍摄,但是..
数据适配器需要几个命令来更新/删除/插入您的 Access 表。看起来您已经使用 Command Builder 构建了 Update 命令,Data Adapter 将使用该命令来更新需要更新的行。此外,您还需要使用 Command Builder 来构建 Insert 和 Delete 命令:
da.InsertCommand = cb.GetInsertCommand
da.DeleteCommand = cb.GetDeleteCommand
“更新需要有效的 InsertCommand”错误告诉您数据适配器不知道如何将您在数据表中创建的新行插入到 Access DB,因为您没有告诉它要使用什么插入命令。插入上面的两行应该可以解决这个问题。
数据适配器上的 InsertCommand、DeleteCommand 和 UpdateCommand 只是数据适配器用于更新基础数据源(在本例中为 Access)的 SQL 语句。您可以手动提供这些命令,也可以将 CommandBuilder 用于类似这种简单的情况。
当您告诉 DataAdapter 进行更新时,它会循环遍历数据表并针对每一行确定该行是否已添加、删除或更新。然后它会寻找适当的命令来执行插入、删除或更新的 SQL 语句。如果您没有提供命令,则会收到您所看到的错误。
编辑:这是您更新的代码以修复“SelectCommand 未初始化”错误和其他一些问题:
Sub prcChoose()
'Always create disposable objects with a Using statement.
'This ensures that the objects will be disposed properly.
Using conn As New OleDbConnection(ConfigurationManager.ConnectionStrings("dbConnection").ConnectionString), _
da As New OleDbDataAdapter("SELECT * FROM ParentPreference", conn), _
cb As New OleDbCommandBuilder(da)
'Open connection.
conn.Open()
'Create new dataset.
Dim ds As New DataSet
'Fill dataset.
da.Fill(ds, "Choice")
'Create new row and populate it.
Dim NewRow As Data.DataRow = ds.Tables("Choice").NewRow()
NewRow.Item(0) = txtUser.Text
NewRow.Item(1) = dropdown.SelectedValue
'Add row to Choice table.
ds.Tables("Choice").Rows.Add(NewRow)
'Use command builder to generate Update, Insert, Delete commands for DataAdapter.
da.UpdateCommand = cb.GetUpdateCommand
da.InsertCommand = cb.GetInsertCommand
da.DeleteCommand = cb.GetDeleteCommand
'Use dataadapter to update datasource.
da.Update(ds, "Choice")
End Using
End Sub
关于asp.net - 如何在 asp .NET 中向数据库添加记录,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/9079498/