我有一个这样定义类型的头文件
#ifndef SETSIZE
#define SETSIZE 32
#endif
typedef struct _set {
unsigned array[SETSIZE];
} set_t;
要使用相应的 C 函数,我需要在 Ada 中使用 set_t 类型。问题在于 SETSIZE 是一个可配置参数(默认值为 32)。如果我理解正确,我无法从 Ada 访问预处理器定义。 是否可以向 c 文件添加一个常量并像这样在 Ada 中使用它:
#ifndef SETSIZE
#define SETSIZE 32
#endif
const size_t test = SETSIZE;
// Alternative
enum { test2 = SETSIZE };
--Ada--
-- import test somehow
type set_array is array (0 .. test) of aliased Interfaces.C.unsigned;
type set_t is record
array_field : aliased set_array;
end record;
或者在 Ada 中正确使用这种类型而无需对原始 C 代码进行太多更改的任何其他方式
最佳答案
为什么不简单:
SetSize: constant Interfaces.C.Size_T;
pragma Import(
Convention => C,
Entity => SetSize,
External_Name => "set_size"
);
在你的 C
文件中:
const size_t set_size = SETSIZE;
使用 gnatmake 4.8.1
测试:
// File: set_def.c
#include <stdlib.h>
#ifndef SETSIZE
#define SETSIZE 32
#endif
const size_t set_size = SETSIZE ;
typedef struct _set {
unsigned array[SETSIZE];
} set_t;
编译set_def.c
:
Z:\> gcc -c set_def.c
-- File: main.adb
with Interfaces.C, Ada.Text_IO, Ada.Integer_Text_IO ;
procedure Main is
use type Interfaces.C.Size_T ; -- To have access to the - operator
SetSize: constant Interfaces.C.Size_T;
pragma Import (
Convention => C,
Entity => SetSize,
External_Name => "set_size"
);
-- Note that you should go to SetSize - 1
type Set_Array is array(0 .. SetSize - 1) of aliased Interfaces.C.Unsigned;
type Set_T is
record
Array_Field: aliased Set_Array;
end record;
MySet: Set_T := (Array_Field => (1, 2, 3, others => 0));
begin
Ada.Integer_Text_IO.Put (Integer(SetSize), 0); Ada.Text_IO.New_Line;
Ada.Integer_Text_IO.Put (MySet.Array_Field'Length, 0); Ada.Text_IO.New_Line;
for I in MySet.Array_Field'range loop
Ada.Integer_Text_IO.Put (Integer(MySet.Array_Field(I)), 0);
Ada.Text_IO.Put(' ');
end loop;
end Main;
编译main.adb
并与set_def.o
链接:
Z:\> gnatmake main.adb -largs set_def.o
Z:\> main.exe
32
32
1 2 3 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0
关于c - 从 Ada 访问 c 常量,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/32079775/