好的,我想应用一个 XSL 样式表来计算先前的唯一“ROLE”节点,并吐出以下输出格式 @name 当前节点之前的唯一 ROLE 节点数。我已经在应该很容易实现的事情上浪费了几个小时。我尝试以多种方式实现这一点,包括 Muenchian 方法、if/with 变量(不能增加变量)、将模板应用到模板等,但均无济于事。
我有以下 XML:
<ROLEACTIONINFO>
<ROLE name="TESTER" />
<ROLE name="PARENT1"/>
<ROLE name="PARENT1"/>
<ROLE name="PARENT1"/>
<ROLE name="PARENT2"/>
<ROLE name="PARENT2"/>
<ROLE name="PARENT3"/>
<ROLE name="PARENT4"/>
<ROLE name="TESTROLE"/>
</ROLEACTIONINFO>
输出示例:
TESTER 1
PARENT1 2
PARENT1 2
PARENT1 2
PARENT2 3
PARENT2 3
PARENT3 4
PARENT4 5
TESTROLE 6
获取唯一先行节点的计数是我的问题。任何帮助将不胜感激
最佳答案
使用 XPath 可以很容易地解决这个问题。这是您要查找的表达式:count((.|preceding-sibling::ROLE)[not(@name = preceding-sibling::ROLE/@name)])
这可以分解以使其更具可读性,正如我在以下 XSLT 1.0 样式表中所做的那样:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
<!-- don't copy whitespace -->
<xsl:template match="text()"/>
<xsl:template match="ROLE">
<xsl:variable name="roles-so-far" select=". | preceding-sibling::ROLE"/>
<!-- Only select the first instance of each ROLE name -->
<xsl:variable name="roles-so-far-unique"
select="$roles-so-far[not(@name = preceding-sibling::ROLE/@name)]"/>
<xsl:apply-templates select="@name"/>
<xsl:text> </xsl:text>
<xsl:value-of select="count($roles-so-far-unique)"/>
<xsl:text>
</xsl:text> <!-- linefeed -->
</xsl:template>
</xsl:stylesheet>
这是一个替代实现,使用 Muenchian 方法。首先,声明一个 key :
<xsl:key name="roles" match="ROLE" use="@name"/>
然后,将 $roles-so-far-unique 的定义替换为如下内容:
<!-- Among all the ROLEs having one of the names so far,
select only the first one for each name -->
<xsl:variable name="roles-so-far-unique"
select="../ROLE[@name = $roles-so-far/@name]
[generate-id(.) = generate-id(key('roles',@name)[1])]"/>
这段代码当然更复杂。除非您有一个大型数据集需要您使用 Muenchian 方法加快处理速度(即便如此我会测试以确保它能为您带来任何好处),否则您不妨坚持使用上面的更简单的版本。
最后,在 XSLT 2.0 中,这要容易得多。简单地将 $roles-so-far-unique 定义替换为以下内容:
<!-- Return a list of distinct string values, with duplicates removed -->
<xsl:variable name="roles-so-far-unique"
select="distinct-values($roles-so-far/@name)"/>
我希望这能帮助您确定在您提到的各种尝试中哪里出了问题。
关于xml - XSL : Counting Previous Unique Siblings,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/941662/