xml - 基于属性值创建父子元素并抑制输出中的重复元素

标签 xml xslt xslt-1.0

作为 XSLT 的新手，我正在尝试使用 XSLT 1.0 转换以下描述对象的 XML:

<Data>
    <Object>
        <Property Name="Id" Value="001"/>
        <Property Name="P.Id" Value="Id P"/>
        <Property Name="P.Description" Value="Descr P"/>
        <Property Name="A.Id" Value="Id A" />
        <Property Name="A.Description" Value="Descr A"/>
        <Property Name="B.Id" Value="Id B"/>
        <Property Name="B.Description" Value="Descr B"/>
        <Property Name="C.Id" Value="" />
        <Property Name="C.Description" Value=""/>
    </Object>
    <Object>
        <Property Name="Id" Value="002"/>
        <Property Name="P.Id" Value="Id P"/>
        <Property Name="P.Description" Value="Descr P"/>
        <Property Name="A.Id" Value="" />
        <Property Name="A.Description" Value=""/>
        <Property Name="B.Id" Value="Id B"/>
        <Property Name="B.Description" Value="Descr B"/>
        <Property Name="C.Id" Value="Id C" />
        <Property Name="C.Description" Value="Descr C"/>
    </Object>
</Data>

应遵循以下规则以获得所需的输出:

  1. 对于每个不包含分隔符“.”的“属性”元素在“名称”属性中，将“名称”属性转换为子元素并选择其“值”属性的值。
  2. 对于每个确实包含分隔符“.”的“属性”元素在“名称”属性中，创建:
    • a) 在“Name”属性中使用“substring-before”分隔符的父元素，以及
    • b) 在“Name”属性中使用“substring-after”分隔符的子元素，并选择其“Value”属性的值。
  3. (2) 的附加规则:
    • a) 如果要创建的“Name”属性中的“substring-before”存在于预定义数组中并且“Value”属性有一个值，将输出元素名称替换为预定义的元素名称。
    • b) 对于 (3a) 适用的所有元素，仅返回输出中第一次出现的元素 - 即跳过后续也可能出现在数组中的元素。

因此，所需的输出应如下所示:

<?xml version="1.0" encoding="UTF-8"?>
<Root>
    <ObjectData>
        <Id>001</Id>
        <P>
            <Id>Id P</Id>
            <Description>Descr P</Description>
        </P>
        <Destination>
            <Type>A</Type>
            <Id>Id A</Id>
            <Description>Descr A</Description>
        </Destination>
    </ObjectData>
    <ObjectData>
        <Id>002</Id>
        <P>
            <Id>Id P</Id>
            <Description>Descr P</Description>
        </P>
        <Destination>
            <Type>B</Type>
            <Id>Id B</Id>
            <Description>Descr B</Description>
        </Destination>
    </ObjectData>
</Root>

目前我有以下代码:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" encoding="UTF-8" indent="yes" omit-xml-declaration="no"/>
    <xsl:strip-space elements="*"/>

    <!-- Define keys -->
    <xsl:key name="kPropertyByName" match="Property[contains(@Name, '.')]" use="concat(generate-id(..), '|', substring-before(@Name,'.'))"/>

    <!-- Define variables -->
    <xsl:variable name="vDestinationArray" select="'A,B,C'" />

    <!-- Identity transform -->
    <xsl:template match="@* | node()" name="Identity">
       <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
       </xsl:copy>
    </xsl:template>

    <!-- Match Data -->
    <xsl:template match="Data" name="Data">
        <xsl:element name="Root">
            <xsl:for-each select="Object">
                <xsl:element name="ObjectData">
                    <xsl:call-template name="Object" />
                </xsl:element>
            </xsl:for-each>
        </xsl:element>
    </xsl:template>

    <!-- Match Object -->
    <xsl:template match="Object" name="Object">
        <!-- For each 'Property'-element that does *not* contain separator '.' in 'Name'-attribute, just select value as-is-->
        <xsl:for-each select="Property[not(contains(@Name, '.'))]">
            <xsl:element name="{@Name}">
                <xsl:value-of select="@Value"/>
            </xsl:element>
        </xsl:for-each>
        <!-- For each 'Property'-element that *does* contain separator '.' in 'Name'-attribute, create a parent element using substring-before separator-->
        <xsl:for-each select="Property[generate-id(.) = generate-id(key('kPropertyByName',concat(generate-id(..), '|', substring-before(@Name,'.')))[1])]">
            <!-- Determine whether parent exists in 'array'-variable -->
            <xsl:choose>
                <!-- Parent *does* exists in 'array'-variable -->
                <xsl:when test="contains(concat(',',$vDestinationArray,','),concat(',',substring-before(@Name,'.'),','))">
                    <xsl:choose>
                        <!-- If value is not empty, create 'Destination'-element -->
                        <xsl:when test="@Value!=''">
                                <xsl:element name="Destination">
                                <xsl:element name="Type">
                                    <xsl:value-of select="substring-before(@Name,'.')" />
                                </xsl:element>
                                <xsl:for-each select="key('kPropertyByName', concat(generate-id(..), '|', substring-before(@Name,'.')))">
                                    <xsl:element name="{substring-after(@Name,'.')}">
                                        <xsl:value-of select="@Value"/>
                                    </xsl:element>
                                </xsl:for-each>                             
                            </xsl:element>
                        </xsl:when>
                    </xsl:choose>
                </xsl:when>
                <!-- Parent does *not* exists in 'array'-variable -->                           
                <xsl:otherwise>
                    <!-- Create child element using substring-after separator -->
                    <xsl:element name="{substring-before(@Name,'.')}">
                        <xsl:for-each select="key('kPropertyByName', concat(generate-id(..), '|', substring-before(@Name,'.')))">
                            <xsl:element name="{substring-after(@Name,'.')}">
                                <xsl:value-of select="@Value"/>
                            </xsl:element>
                        </xsl:for-each>
                    </xsl:element>                          
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

这给了我以下输出 - 具有(不需要的)重复“目标”元素:

<?xml version="1.0" encoding="UTF-8"?>
<Root>
    <ObjectData>
        <Id>001</Id>
        <P>
            <Id>Id P</Id>
            <Description>Descr P</Description>
        </P>
        <Destination>
            <Type>A</Type>
            <Id>Id A</Id>
            <Description>Descr A</Description>
        </Destination>
        <Destination>
            <Type>B</Type>
            <Id>Id B</Id>
            <Description>Descr B</Description>
        </Destination>
    </ObjectData>
    <ObjectData>
        <Id>002</Id>
        <P>
            <Id>Id P</Id>
            <Description>Descr P</Description>
        </P>
        <Destination>
            <Type>B</Type>
            <Id>Id B</Id>
            <Description>Descr B</Description>
        </Destination>
        <Destination>
            <Type>C</Type>
            <Id>Id C</Id>
            <Description>Descr C</Description>
        </Destination>
    </ObjectData>
</Root>

不是我要找的...任何帮助将不胜感激!

最佳答案

这是一个更短/更简单的(没有xsl:if，没有xsl:key，没有generate-id() )解决方案:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my" extension-element-prefixes="my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>
 <my:names>
   <n>A</n>
   <n>B</n>
   <n>C</n>
 </my:names>

 <xsl:template match="*">
  <Root><xsl:apply-templates/></Root>
 </xsl:template>

 <xsl:template match="/*/*">
  <ObjectData><xsl:apply-templates/></ObjectData>
 </xsl:template>

 <xsl:template match="Property[not(contains(@Name, '.'))]">
  <xsl:element name="{@Name}">
   <xsl:value-of select="@Value"/>
  </xsl:element>
 </xsl:template>

 <xsl:template match="Property">
  <xsl:element name="{substring-before(@Name, '.')}">
    <xsl:element name="{substring-after(@Name, '.')}">
       <xsl:value-of select="@Value"/>
    </xsl:element>
    <xsl:apply-templates mode="descr"  select=
     "../*[@Name = concat(substring-before(current()/@Name, '.'),'.','Description')]"/>
  </xsl:element>
 </xsl:template>

 <xsl:template match=
  "Property[string(@Value) and contains(@Name, '.')
  and substring-before(@Name, '.') = document('')/*/my:names/*]
  [1]
  ">
   <Destination>
       <Type><xsl:value-of select="substring-before(@Name, '.')"/></Type>
       <xsl:element name="{substring-after(@Name, '.')}">
           <xsl:value-of select="@Value"/>
       </xsl:element>
     <xsl:apply-templates mode="descr" select=
     "../*[@Name = concat(substring-before(current()/@Name, '.'),'.','Description')]"/>

   </Destination>
 </xsl:template>

  <xsl:template match=
  "Property[contains(@Name, '.')
          and substring-before(@Name, '.') = document('')/*/my:names/*
          and not(string(@Value))
           ]"/>
  <xsl:template match=
  "Property[contains(@Name, '.')
          and substring-before(@Name, '.') = document('')/*/my:names/*
          and string(@Value)
           ][not(position() = 1)]"/>
 <xsl:template match="*[substring-after(@Name,'.') = 'Description']"/>

 <xsl:template match="*" mode="descr">
  <Description><xsl:apply-templates select="@Value"/></Description>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时:

<Data>
    <Object>
        <Property Name="Id" Value="001"/>
        <Property Name="P.Id" Value="Id P"/>
        <Property Name="P.Description" Value="Descr P"/>
        <Property Name="A.Id" Value="Id A" />
        <Property Name="A.Description" Value="Descr A"/>
        <Property Name="B.Id" Value="Id B"/>
        <Property Name="B.Description" Value="Descr B"/>
        <Property Name="C.Id" Value="" />
        <Property Name="C.Description" Value=""/>
    </Object>
    <Object>
        <Property Name="Id" Value="002"/>
        <Property Name="P.Id" Value="Id P"/>
        <Property Name="P.Description" Value="Descr P"/>
        <Property Name="A.Id" Value="" />
        <Property Name="A.Description" Value=""/>
        <Property Name="B.Id" Value="Id B"/>
        <Property Name="B.Description" Value="Descr B"/>
        <Property Name="C.Id" Value="Id C" />
        <Property Name="C.Description" Value="Descr C"/>
    </Object>
</Data>

产生了想要的、正确的结果:

<Root>
   <ObjectData>
      <Id>001</Id>
      <P>
         <Id>Id P</Id>
         <Description>Descr P</Description>
      </P>
      <Destination>
         <Type>A</Type>
         <Id>Id A</Id>
         <Description>Descr A</Description>
      </Destination>
   </ObjectData>
   <ObjectData>
      <Id>002</Id>
      <P>
         <Id>Id P</Id>
         <Description>Descr P</Description>
      </P>
      <Destination>
         <Type>B</Type>
         <Id>Id B</Id>
         <Description>Descr B</Description>
      </Destination>
   </ObjectData>
</Root>

关于xml - 基于属性值创建父子元素并抑制输出中的重复元素，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/16425670/

上一篇：xml - cvc-elt.1.a : Cannot find the declaration of element 'xxx'

下一篇：C# XML Schema 验证

相关文章：

Java:IndentingXMLStreamWriter 替代方案？

android - 解析 XML 时出错 : not well-formed (invalid token) andElement type "LinearLayout" must be followed by either attribute specifications, ">"或 "/>"

xslt - xpath:number 为 "0"返回 false

xslt - XSLT模板和递归

xslt-1.0 - 调用XSLT模板并将所有输出保存到变量

xml - 如何使用 xslt 中的 xml 数据源将 unicode 转换为 iso？

java - SimpleXML Java 添加类作为元素

java - 解析 XML，跳过某些标签

xslt - 包含一个带有 XSLT 1.0 的纯文本文件

xslt - 如何使用 xsl 1.0 找到最小值和最大值？

©2024 IT工具网  联系我们