我不能有任何嵌套跨度，所以我需要将它们展平并连接它们的类属性，以便我可以跟踪哪些类是父类。
这是一个简化的输入:
<body>
<h1 class="section">Title</h1>
<p class="main">
ZZZ
<span class="a">
AAA
<span class="b">
BBB
<span class="c">
CCC
<preserveMe>
eeee
</preserveMe>
</span>
bbb
<preserveMe>
eeee
</preserveMe>
</span>
aaa
</span>
</p>
</body>
这是期望的输出
<body>
<h1 class="section">Title</h1>
<p class="main">
ZZZ
<span class="a">
AAA
</span>
<span class="ab">
BBB
</span>
<span class="abc">
CCC
<preserveMe>
eeee
</preserveMe>
</span>
<span class="ab">
bbb
<preserveMe>
eeee
</preserveMe>
</span>
<span class="a">
aaa
</span>
</p>
</body>
这是我最接近的(我对此很陌生，所以即使走到这一步也花了我很长时间......)
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="/">
<p>
<xsl:apply-templates/>
</p>
</xsl:template>
<xsl:template match="*/span">
<span class='{concat(../../@class,../@class,@class)}'>
<xsl:value-of select='.'/>
</span>
<xsl:apply-templates/>
</xsl:template>
</xsl:stylesheet>
如果您自己运行，您可以看到我失败尝试的结果以及与我真正想要的结果相差多远。理想情况下，我想要一个接受任意数量嵌套级别并且还可以处理中断嵌套(span、span、notSpan、span...)的解决方案。
编辑:我根据下面评论者的请求在嵌套结构中添加了标签。另外，我使用的是 XSLT v1.0，但我想如果需要我可以使用其他版本。
编辑 2:我意识到与我实际需要转换的内容相比，我的示例过度简化了。即，我不能丢失其他标签的类；只有 span 可以组合。
最佳答案
正如我在开场评论中提到的，这远非微不足道。这是您可以考虑的另一种方法:
XSLT 1.0
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<!-- identity transform -->
<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="p">
<xsl:copy>
<xsl:apply-templates select="@*|node()|.//span/text()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="span/text()">
<span>
<xsl:attribute name="class">
<xsl:for-each select="ancestor::span">
<xsl:value-of select="@class"/>
</xsl:for-each>
</xsl:attribute>
<xsl:apply-templates select="preceding-sibling::*"/>
<xsl:value-of select="." />
<xsl:if test="not(following-sibling::text())">
<xsl:apply-templates select="following-sibling::*"/>
</xsl:if>
</span>
</xsl:template>
<xsl:template match="span"/>
</xsl:stylesheet>
这在很大程度上类似于 Lingamurthy CS 之前提出的建议 - 但您会看到以下测试输入的不同之处:
XML
<body>
<h1 class="section">Title</h1>
<p class="main">
ZZZ
<preserveMe>0</preserveMe>
<span class="a">
AAA
<span class="b">
BBB
<span class="c">
CCC
<preserveMe>c</preserveMe>
</span>
bbb
<preserveMe>b</preserveMe>
</span>
aaa
</span>
<preserveMe>1</preserveMe>
</p>
</body>
关于xml - 使用 XSLT 拆分和展平节点，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/29711224/